source: trunk/processor/struct.m4 @ 877

Last change on this file since 877 was 877, checked in by moo, 2 years ago

kill warning

  • Property svn:eol-style set to native
File size: 6.9 KB
Line 
1define(`pushdefFUNC_NAME', `
2    pushdef(`FUNC_NAME', `xc_`'PROCESSOR_TYPE`'_`'ifelse(`$2', `', `$1', `$2')')
3')
4dnl {{{ DECL_STRUCT_P_FUNC(1:type, 2:name, 3:comma=;)
5define(`DECL_STRUCT_P_FUNC', `translit(
6    pushdefFUNC_NAME(`$1', `$2')
7    define(`DEFINED_'ifelse(`$2', `', `$1', `$2'), `')
8    ifdef(`EXPORT_'ifelse(`$2', `', `$1', `$2'), `void', `static void inline')
9    FUNC_NAME`'(
10        IFDPRINT( `const $1 * const src, int indent')
11        IFCALC(   `xc_processor_t *processor, const $1 * const src')
12        IFSTORE(  `xc_processor_t *processor, $1 *dst, const $1 * const src')
13        IFRESTORE(`xc_processor_t *processor, $1 *dst, const $1 * const src')
14        IFDASM(   `zval *dst, const $1 * const src')
15        IFASM(    `$1 *dst, const $1 * const src')
16        TSRMLS_DC
17    )ifelse(`$3', `', `;')
18    popdef(`FUNC_NAME')dnl
19, `
20', ` ')')
21dnl }}}
22dnl {{{ DEF_STRUCT_P_FUNC(1:type, 2:name, 3:body)
23define(`DEF_STRUCT_P_FUNC', `
24    pushdefFUNC_NAME(`$1', `$2')
25/* {`{'{ FUNC_NAME */
26    ifdef(`EXPORT_'ifelse(`$2', `', `$1', `$2'), `
27        /* export: DECL_STRUCT_P_FUNC(`$1', `$2') :export */
28    ')
29DECL_STRUCT_P_FUNC(`$1', `$2', 1)
30    {
31        pushdef(`ELEMENTS_DONE')
32        IFAUTOCHECK(`
33            /* {{{ init assert */
34            ifdef(`SIZEOF_$1', , `m4_errprint(`missing SIZEOF_$1, safe to ignore')')
35            ifdef(`COUNTOF_$1', , `m4_errprint(`missing COUNTOF_$1, safe to ignore')')
36            dnl SIZEOF_x COUNTOF_x can be both defined or both not
37            ifdef(`SIZEOF_$1', `
38                ifdef(`COUNTOF_$1', , `m4_errprint(`AUTOCHECK WARN: missing COUNTOF_$1')')
39            ', `
40                define(`SIZEOF_$1', 0)
41            ')
42            ifdef(`COUNTOF_$1', `
43                ifdef(`SIZEOF_$1', , `m4_errprint(`AUTOCHECK WARN: missing SIZEOF_$1')')
44            ', `
45                define(`COUNTOF_$1', 0)
46            ')
47            int xc_autocheck_assert_size = SIZEOF_$1, assert_count = COUNTOF_$1;
48            int xc_autocheck_done_size = 0, xc_autocheck_done_count = 0;
49            const char *xc_autocheck_assert_names[] = { ifdef(`ELEMENTSOF_$1', `ELEMENTSOF_$1') };
50            zend_bool xc_autocheck_skip = 0;
51            HashTable xc_autocheck_done_names;
52            zend_hash_init(&xc_autocheck_done_names, 0, NULL, NULL, 0);
53            /* }}} */
54            IFRESTORE(`assert(xc_is_shm(src));')
55            IFCALCSTORE(`assert(!xc_is_shm(src));')
56            do {
57        ')
58        ifdef(`SIZEOF_$1', , `m4_errprint(`AUTOCHECK WARN: $1: missing structinfo, dont panic')')
59
60        ifdef(`USEMEMCPY', `IFCOPY(`
61            memcpy(dst, src, sizeof($1));
62            do {
63        ')')
64
65        IFDPRINT(`
66            fprintf(stderr, "%s", "{\n");
67            indent ++;
68        ')
69        $3`'
70        IFDPRINT(`
71            indent --;
72            INDENT()fprintf(stderr, "}\n");
73        ')
74        IFAUTOCHECK(`
75        /* {{{ autocheck */ if (!xc_autocheck_skip) {
76            int name_check_errors = xc_check_names(__FILE__, __LINE__, "FUNC_NAME", xc_autocheck_assert_names, sizeof(xc_autocheck_assert_names) / sizeof(xc_autocheck_assert_names[0]), &xc_autocheck_done_names);
77            zend_hash_destroy(&xc_autocheck_done_names);
78
79            if (xc_autocheck_done_count != assert_count) {
80                fprintf(stderr
81                    , "count assertion failed at %s `#'%d FUNC_NAME`' : unexpected:%d - expecting:%d = %d != 0\n"
82                    , __FILE__, __LINE__
83                    , xc_autocheck_done_count, assert_count, xc_autocheck_done_count - assert_count
84                    );
85            }
86            if (xc_autocheck_done_size != xc_autocheck_assert_size) {
87                fprintf(stderr
88                    , "size assertion failed at %s `#'%d FUNC_NAME`' : unexpected:%d - expecting:%d = %d != 0\n"
89                    , __FILE__, __LINE__
90                    , xc_autocheck_done_size, xc_autocheck_assert_size, xc_autocheck_done_size - xc_autocheck_assert_size
91                    );
92            }
93            if (name_check_errors || xc_autocheck_done_count != assert_count || xc_autocheck_done_size != xc_autocheck_assert_size) {
94                assert(0);
95            }
96        } while (0); /* }}} */
97        ')
98        ifdef(`ELEMENTSOF_$1', `
99            pushdef(`ELEMENTS_UNDONE', LIST_DIFF(defn(`ELEMENTSOF_$1'), defn(`ELEMENTS_DONE')))
100            ifelse(defn(`ELEMENTS_UNDONE'), , `m4_errprint(`AUTOCHECK INFO: $1: processor looks good')', `
101                m4_errprint(`AUTOCHECK ERROR: ====' PROCESSOR_TYPE `$1 =================')
102                m4_errprint(`AUTOCHECK expected:' defn(`ELEMENTSOF_$1'))
103                m4_errprint(`AUTOCHECK missing :' defn(`ELEMENTS_UNDONE'))
104                define(`EXIT_PENDING', 1)
105            ')
106            popdef(`ELEMENTS_UNDONE')
107        ')
108        ifdef(`USEMEMCPY', `IFCOPY(`
109            } while (0);
110        ')')
111        IFAUTOCHECK(`
112            } while (0);
113        ')
114        popdef(`ELEMENTS_DONE')
115    }
116/* }`}'} */
117    popdef(`FUNC_NAME')
118')
119dnl }}}
120dnl {{{ STRUCT_P_EX(1:type, 2:dst, 3:src, 4:elm-name, 5:name=type, 6:&)
121define(`STRUCT_P_EX', `
122    DBG(`$0($*)')
123    pushdefFUNC_NAME(`$1', `$5')
124    ifdef(`DEFINED_'ifelse(`$5', `', `$1', `$5'), `', `m4_errprint(`AUTOCHECK ERROR: Unknown struct "'ifelse(`$5', `', `$1', `$5')`"')define(`EXIT_PENDING', 1)')
125    assert(sizeof($1) == sizeof(($6 $3)[0]));
126    ifelse(`$6', `', `ALLOC(`$2', `$1')')
127    IFDASM(`do {
128        zval *zv;
129        ALLOC_INIT_ZVAL(zv);
130        array_init(zv);
131    ')
132    FUNC_NAME`'(
133        IFDPRINT( `           $6 $3, indent')
134        IFCALC(   `processor, $6 $3')
135        IFSTORE(  `processor, $6 $2, $6 $3')
136        IFRESTORE(`processor, $6 $2, $6 $3')
137        IFDASM(   `zv, $6 $3')
138        IFASM(    `$6 $2, $6 $3')
139        TSRMLS_CC
140    );
141    IFDASM(`
142        add_assoc_zval_ex(dst, ZEND_STRS("$4"), zv);
143    } while (0);
144    ')
145    popdef(`FUNC_NAME')
146    ifelse(`$6', , `FIXPOINTER_EX(`$1', `$2')')
147')
148dnl }}}
149dnl {{{ STRUCT_P(1:type, 2:elm, 3:name=type)
150define(`STRUCT_P', `
151    DBG(`$0($*)')
152    if (SRC(`$2')) {
153        IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2 ");')
154        STRUCT_P_EX(`$1', `dst->$2', `SRC(`$2')', `$2', `$3')
155    }
156    else {
157        IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2:\tNULL\n");')
158        COPYNULL_EX(`dst->$2', `$2')
159    }
160    DONE(`$2')
161')
162dnl }}}
163dnl {{{ STRUCT(1:type, 2:elm, 3:name=type)
164define(`STRUCT', `
165    DBG(`$0($*)')
166    assert(sizeof($1) == sizeof(SRC(`$2')));
167    IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2 ");')
168    STRUCT_P_EX(`$1', `dst->$2', `SRC(`$2')', `$2', `$3', `&')
169    DONE(`$2')
170')
171dnl }}}
172dnl {{{ STRUCT_ARRAY(1:count, 2:type, 3:elm, 4:name=type, 5:loopcounter)
173define(`STRUCT_ARRAY', `
174    if (SRC(`$3')) {
175        ifelse(
176            `$5', `', `int i; pushdef(`LOOPCOUNTER', `i')',
177            `', `', `pushdef(`LOOPCOUNTER', `$5')')
178        pushdefFUNC_NAME(`$2', `$4')
179        IFDASM(`
180            zval *arr;
181            ALLOC_INIT_ZVAL(arr);
182            array_init(arr);
183
184            for (LOOPCOUNTER = 0;
185                    ifelse(`$1', `', `SRC(`$3[LOOPCOUNTER]')',
186                    `', `', `LOOPCOUNTER < SRC(`$1')');
187                    ++LOOPCOUNTER) {
188                zval *zv;
189
190                ALLOC_INIT_ZVAL(zv);
191                array_init(zv);
192                FUNC_NAME (zv, &(SRC(`$3[LOOPCOUNTER]')) TSRMLS_CC);
193                add_next_index_zval(arr, zv);
194            }
195            add_assoc_zval_ex(dst, ZEND_STRS("$3"), arr);
196        ', `
197            dnl find count with NULL
198            ifelse(`$1', `', `
199                size_t count = 0;
200                while (SRC(`$3[count]')) {
201                    ++count;
202                }
203                ++count;
204                pushdef(`ARRAY_ELEMENT_COUNT', `count')
205            ',
206            `', `', `pushdef(`ARRAY_ELEMENT_COUNT', `SRC(`$1')')')
207            ALLOC(`dst->$3', `$2', `ARRAY_ELEMENT_COUNT')
208            popdef(`ARRAY_ELEMENT_COUNT')
209
210            for (LOOPCOUNTER = 0;
211                    ifelse(`$1', `', `SRC(`$3[LOOPCOUNTER]')',
212                    `', `', `LOOPCOUNTER < SRC(`$1')');
213                    ++LOOPCOUNTER) {
214                DISABLECHECK(`
215                    STRUCT(`$2', `$3[LOOPCOUNTER]', `$4')
216                ')
217            }
218            dnl the end marker
219            ifelse(`$1', `', `IFCOPY(`DST(`$3[LOOPCOUNTER]') = NULL;')')
220        ')dnl IFDASM
221        DONE(`$3')
222        popdef(`FUNC_NAME')
223        popdef(`LOOPCOUNTER')
224    }
225    else {
226        COPYNULL(`$3')
227    }
228')
229dnl }}}
Note: See TracBrowser for help on using the repository browser.