source: trunk/processor/struct.m4 @ 178

Last change on this file since 178 was 178, checked in by moo, 8 years ago

Processor: fix type processor_t conflict with Mac OS X

File size: 5.8 KB
Line 
1define(`pushdefFUNC_NAME', `
2    pushdef(`FUNC_NAME', `xc_`'KIND`'_`'ifelse(`$2', `', `$1', `$2')')
3')
4dnl {{{ DECL_STRUCT_P_FUNC(1:type, 2:name, 3:comma=;)
5define(`DECL_STRUCT_P_FUNC', `translit(
6    pushdefFUNC_NAME(`$1', `$2')
7    define(`DEFINED_'ifelse(`$2', `', `$1', `$2'), `')
8    ifdef(`EXPORT_'ifelse(`$2', `', `$1', `$2'), `void', `static void inline')
9    FUNC_NAME`'(
10        IFDPRINT( `const $1 * const src, int indent')
11        IFCALC(   `xc_processor_t *processor, const $1 * const src')
12        IFSTORE(  `xc_processor_t *processor, $1 *dst, const $1 * const src')
13        IFRESTORE(`xc_processor_t *processor, $1 *dst, const $1 * const src')
14        IFDASM(   `zval *dst, const $1 * const src')
15        IFASM(    `$1 *dst, const $1 * const src')
16        TSRMLS_DC
17    )ifelse(`$3', `', `;')
18    popdef(`FUNC_NAME')dnl
19, `
20', ` ')')
21dnl }}}
22dnl {{{ DEF_STRUCT_P_FUNC(1:type, 2:name, 3:body)
23define(`DEF_STRUCT_P_FUNC', `
24    pushdefFUNC_NAME(`$1', `$2')
25/* {`{'{ FUNC_NAME */
26    ifdef(`EXPORT_'ifelse(`$2', `', `$1', `$2'), `
27        /* export: DECL_STRUCT_P_FUNC(`$1', `$2') :export */
28    ')
29DECL_STRUCT_P_FUNC(`$1', `$2', 1)
30    {
31        pushdef(`ELEMENTS_DONE')
32        ifdef(`SIZEOF_$1', , `m4_errprint(`AUTOCHECK WARN: $1: missing structinfo, dont panic')define(`SIZEOF_$1', 0)')
33        IFASSERT(`
34            /* {{{ init assert */
35            ifdef(`SIZEOF_$1', , `m4_errprint(`missing SIZEOF_$1, safe to ignore')define(`SIZEOF_$1', 0)')
36            ifdef(`COUNTOF_$1', , `m4_errprint(`missing COUNTOF_$1, safe to ignore')define(`COUNTOF_$1', 0)')
37            dnl SIZEOF_x COUNTOF_x can be both defined or both not
38            ifdef(`SIZEOF_$1', `
39                ifdef(`COUNTOF_$1', , `m4_errprint(`AUTOCHECK WARN: missing COUNTOF_$1')')
40            ', `
41                define(`SIZEOF_$1', 0)
42            ')
43            ifdef(`COUNTOF_$1', `
44                ifdef(`SIZEOF_$1', , `m4_errprint(`AUTOCHECK WARN: missing SIZEOF_$1')')
45            ', `
46                define(`COUNTOF_$1', 0)
47            ')
48            int assert_size = SIZEOF_$1, assert_count = COUNTOF_$1;
49            int done_size = 0, done_count = 0;
50            /* }}} */
51            IFRESTORE(`assert(xc_is_shm(src));')
52            IFCALCSTORE(`assert(!xc_is_shm(src));')
53            do {
54        ')
55
56        ifdef(`USEMEMCPY', `IFCOPY(`
57            memcpy(dst, src, sizeof($1));
58            do {
59        ')')
60
61        IFDPRINT(`
62            fprintf(stderr, "%s", " {\n");
63            indent ++;
64        ')
65        $3`'
66        IFDPRINT(`
67            indent --;
68            INDENT()fprintf(stderr, "}\n");
69        ')
70        ifdef(`SKIPASSERT_ONCE', `undefine(`SKIPASSERT_ONCE')', `
71            IFASSERT(`
72                /* {{{ check assert */
73                if (done_count != assert_count) {
74                    fprintf(stderr
75                        , "count assertion failed at %s `#'%d FUNC_NAME`' : unexpected:%d - expecting:%d = %d != 0\n"
76                        , __FILE__, __LINE__
77                        , done_count, assert_count, done_count - assert_count
78                        );
79                }
80                if (done_size != assert_size) {
81                    fprintf(stderr
82                        , "size assertion failed at %s `#'%d FUNC_NAME`' : unexpected:%d - expecting:%d = %d != 0\n"
83                        , __FILE__, __LINE__
84                        , done_size, assert_size, done_size - assert_size
85                        );
86                }
87                if (done_count != assert_count || done_size != assert_size) {
88                    assert(0);
89                }
90                /* }}} */
91            ')
92            ifdef(`ELEMENTSOF_$1', `
93                pushdef(`ELEMENTS_UNDONE', LIST_DIFF(defn(`ELEMENTSOF_$1'), defn(`ELEMENTS_DONE')))
94                ifelse(defn(`ELEMENTS_UNDONE'), , `m4_errprint(`AUTOCHECK INFO: $1: processor looks good')', `
95                    m4_errprint(`AUTOCHECK ERROR: ====' KIND `$1 =================')
96                    m4_errprint(`AUTOCHECK expected:' defn(`ELEMENTSOF_$1'))
97                    m4_errprint(`AUTOCHECK missing :' defn(`ELEMENTS_UNDONE'))
98                    define(`EXIT_PENDING', 1)
99                ')
100                popdef(`ELEMENTS_UNDONE')
101            ')
102        ')
103        ifdef(`USEMEMCPY', `IFCOPY(`
104            } while (0);
105        ')')
106        IFASSERT(`
107            } while (0);
108        ')
109        popdef(`ELEMENTS_DONE')
110    }
111/* }`}'} */
112    popdef(`FUNC_NAME')
113')
114dnl }}}
115dnl {{{ STRUCT_P_EX(1:type, 2:dst, 3:src, 4:elm-name, 5:name=type, 6:&)
116define(`STRUCT_P_EX', `
117    DBG(`$0($*)')
118    pushdefFUNC_NAME(`$1', `$5')
119    ifdef(`DEFINED_'ifelse(`$5', `', `$1', `$5'), `', `m4_errprint(`Unknown struct "'ifelse(`$5', `', `$1', `$5')`"')')
120    assert(sizeof($1) == sizeof(($6 $3)[0]));
121    ifelse(`$6', `', `ALLOC(`$2', `$1')')
122    IFDASM(`do {
123        zval *zv;
124        ALLOC_INIT_ZVAL(zv);
125        array_init(zv);
126    ')
127    FUNC_NAME`'(
128        IFDPRINT( `           $6 $3, indent')
129        IFCALC(   `processor, $6 $3')
130        IFSTORE(  `processor, $6 $2, $6 $3')
131        IFRESTORE(`processor, $6 $2, $6 $3')
132        IFDASM(   `zv, $6 $3')
133        IFASM(    `$6 $2, $6 $3')
134        TSRMLS_CC
135    );
136    IFDASM(`
137        add_assoc_zval_ex(dst, ZEND_STRS("$4"), zv);
138    } while (0);
139    ')
140    popdef(`FUNC_NAME')
141    ifelse(`$6', , `FIXPOINTER_EX(`$1', `$2')')
142')
143dnl }}}
144dnl {{{ STRUCT_P(1:type, 2:elm, 3:name=type)
145define(`STRUCT_P', `
146    DBG(`$0($*)')
147    if (src->$2) {
148        STRUCT_P_EX(`$1', `dst->$2', `src->$2', `$2', `$3')
149        IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2");')
150    }
151    else {
152        COPYNULL_EX(`dst->$2', `$2')
153        IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2:\tNULL\n");')
154    }
155    DONE(`$2')
156')
157dnl }}}
158dnl {{{ STRUCT(1:type, 2:elm, 3:name=type)
159define(`STRUCT', `
160    DBG(`$0($*)')
161    assert(sizeof($1) == sizeof(src->$2));
162    IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2");')
163    STRUCT_P_EX(`$1', `dst->$2', `src->$2', `$2', `$3', `&')
164    DONE(`$2')
165')
166dnl }}}
167dnl {{{ STRUCT_ARRAY_I(1:count, 2:type, 3:elm, 4:name=type)
168define(`STRUCT_ARRAY_I', `
169pushdef(`i', `ii')
170STRUCT_ARRAY(`$1', `$2', `$3', `$4')
171popdef(`i')
172')
173dnl }}}
174dnl {{{ STRUCT_ARRAY(1:count, 2:type, 3:elm, 4:name=type)
175define(`STRUCT_ARRAY', `
176    if (src->$3) {
177        pushdefFUNC_NAME(`$2', `$4')
178        IFDASM(`
179            zval *arr;
180            ALLOC_INIT_ZVAL(arr);
181            array_init(arr);
182            for (i = 0; i < src->$1; i ++) {
183                zval *zv;
184
185                ALLOC_INIT_ZVAL(zv);
186                array_init(zv);
187                FUNC_NAME (zv, &(src->$3[i]) TSRMLS_CC);
188                add_next_index_zval(arr, zv);
189            }
190            add_assoc_zval_ex(dst, ZEND_STRS("$3"), arr);
191        ', `
192            ALLOC(`dst->$3', `$2', `src->$1')
193            ifdef(`AFTER_ALLOC', AFTER_ALLOC)
194            for (i = 0; i < src->$1; i ++) {
195                DISABLECHECK(`
196                    ifdef(`BEFORE_LOOP', `BEFORE_LOOP')
197                    STRUCT(`$2', `$3[i]', `$4')
198                ')
199            }
200        ')dnl IFDASM
201        DONE(`$3')
202        popdef(`FUNC_NAME')
203    }
204    else {
205        COPYNULL(`$3')
206        ifdef(`AFTER_ALLOC', AFTER_ALLOC)
207    }
208')
209dnl }}}
Note: See TracBrowser for help on using the repository browser.