source: trunk/processor/struct.m4 @ 1461

Last change on this file since 1461 was 1461, checked in by moo, 11 months ago

relocate: update dst/src to compile

  • Property svn:eol-style set to native
File size: 7.8 KB
Line 
1define(`pushdefFUNC_NAME', `
2    pushdef(`FUNC_NAME', `xc_`'PROCESSOR_TYPE`'_`'ifelse(`$2', `', `$1', `$2')')
3')
4dnl {{{ DECL_STRUCT_P_FUNC(1:type, 2:name, 3:comma=;)
5define(`DECL_STRUCT_P_FUNC', `translit(
6    pushdefFUNC_NAME(`$1', `$2')
7    pushdef(`type', `ifelse(`$2', `', `$1', `$2')')
8    define(`DEFINED_'type, `')
9    ifelse(ifdef(`EXPORT_'PROCESSOR_TYPE`_'type,1)ifdef(`EXPORT_'PROCESSOR_TYPE`_',1)ifdef(`EXPORT__'type,1), `', `static void inline',
10        `', `', `void')
11    popdef(`type')
12    FUNC_NAME`'(
13        IFDPRINT( `const $1 * const src, int indent')
14        IFCALC(   `xc_processor_t *processor, const $1 * const src')
15        IFSTORE(  `xc_processor_t *processor, $1 *dst, const $1 * const src')
16        IFRESTORE(`xc_processor_t *processor, $1 *dst, const $1 * const src')
17        IFRELOCATE(`$1 *const dst, ptrdiff_t ptrdiff, ptrdiff_t relocatediff')
18        IFDASM(`xc_dasm_t *dasm, zval *dst, const $1 * const src')
19        TSRMLS_DC
20    )ifelse(`$3', `', `;')
21    popdef(`FUNC_NAME')dnl
22, `
23', ` ')')
24dnl }}}
25dnl {{{ DEF_STRUCT_P_FUNC(1:type, 2:name, 3:body)
26define(`DEF_STRUCT_P_FUNC', `
27    pushdefFUNC_NAME(`$1', `$2')
28/* {`{'{ FUNC_NAME */
29    pushdef(`type', `ifelse(`$2', `', `$1', `$2')')
30    define(`DEFINED_'type, `')
31    ifelse(ifdef(`EXPORT_'PROCESSOR_TYPE`_'type,1)ifdef(`EXPORT_'PROCESSOR_TYPE`_',1)ifdef(`EXPORT__'type,1), `', `',
32        `', `', `EXPORT(`DECL_STRUCT_P_FUNC(`$1', `$2')')')
33    popdef(`type')
34DECL_STRUCT_P_FUNC(`$1', `$2', ` ')
35    {
36        pushdef(`ELEMENTS_DONE')
37        IFAUTOCHECK(`
38            /* {{{ init assert */
39            ifdef(`SIZEOF_$1', , `m4_errprint(`Warning: missing SIZEOF_$1, safe to ignore')')
40            ifdef(`COUNTOF_$1', , `m4_errprint(`Warning: missing COUNTOF_$1, safe to ignore')')
41            dnl SIZEOF_x COUNTOF_x can be both defined or both not
42            ifdef(`SIZEOF_$1', `
43                ifdef(`COUNTOF_$1', , `m4_errprint(`AUTOCHECK WARN: missing COUNTOF_$1')')
44            ', `
45                define(`SIZEOF_$1', 0)
46            ')
47            ifdef(`COUNTOF_$1', `
48                ifdef(`SIZEOF_$1', , `m4_errprint(`AUTOCHECK WARN: missing SIZEOF_$1')')
49            ', `
50                define(`COUNTOF_$1', 0)
51            ')
52            int xc_autocheck_assert_size = SIZEOF_$1, assert_count = COUNTOF_$1;
53            int xc_autocheck_done_size = 0, xc_autocheck_done_count = 0;
54            ifdef(`ELEMENTSOF_$1', `
55                const char *xc_autocheck_assert_names[] = { ELEMENTSOF_$1 };
56                size_t xc_autocheck_assert_names_count = sizeof(xc_autocheck_assert_names) / sizeof(xc_autocheck_assert_names[0]);
57            ', `
58                const char **xc_autocheck_assert_names = NULL;
59                size_t xc_autocheck_assert_names_count = 0;
60            ')
61            zend_bool xc_autocheck_skip = 0;
62            HashTable xc_autocheck_done_names;
63            zend_hash_init(&xc_autocheck_done_names, 0, NULL, NULL, 0);
64            /* }}} */
65            IFRESTORE(`assert(xc_is_shm(SRC()));')
66            IFCALCSTORE(`assert(!xc_is_shm(SRC()));')
67        ')
68        ifdef(`SIZEOF_$1', , `m4_errprint(`AUTOCHECK WARN: $1: missing structinfo, dont panic')')
69
70        ifdef(`USEMEMCPY', `IFCOPY(`
71            memcpy(DST(), SRC(), sizeof($1));
72        ')')
73
74        IFDPRINT(`
75            fprintf(stderr, "%s", "{\n");
76            indent ++;
77        ')
78        {
79            $3`'
80        }
81        IFDPRINT(`
82            indent --;
83            INDENT()fprintf(stderr, "}\n");
84        ')
85
86        IFAUTOCHECK(`
87        /* {{{ autocheck */
88        if (!xc_autocheck_skip) {
89            int name_check_errors = xc_check_names(__FILE__, __LINE__, "FUNC_NAME", xc_autocheck_assert_names, xc_autocheck_assert_names_count, &xc_autocheck_done_names);
90
91            if (xc_autocheck_done_count != assert_count) {
92                fprintf(stderr
93                    , "count assertion failed at %s `#'%d FUNC_NAME`' : unexpected:%d - expecting:%d = %d != 0\n"
94                    , __FILE__, __LINE__
95                    , xc_autocheck_done_count, assert_count, xc_autocheck_done_count - assert_count
96                    );
97            }
98            if (xc_autocheck_done_size != xc_autocheck_assert_size) {
99                fprintf(stderr
100                    , "size assertion failed at %s `#'%d FUNC_NAME`' : unexpected:%d - expecting:%d = %d != 0\n"
101                    , __FILE__, __LINE__
102                    , xc_autocheck_done_size, xc_autocheck_assert_size, xc_autocheck_done_size - xc_autocheck_assert_size
103                    );
104            }
105            if (name_check_errors || xc_autocheck_done_count != assert_count || xc_autocheck_done_size != xc_autocheck_assert_size) {
106                assert(0);
107            }
108        }
109        zend_hash_destroy(&xc_autocheck_done_names);
110        /* }}} */
111        ')
112        ifdef(`AUTOCHECK_SKIP', `undefine(`AUTOCHECK_SKIP')', `
113            ifdef(`ELEMENTSOF_$1', `
114                pushdef(`ELEMENTS_UNDONE', LIST_DIFF(defn(`ELEMENTSOF_$1'), defn(`ELEMENTS_DONE')))
115                ifelse(defn(`ELEMENTS_UNDONE'), , `m4_errprint(`AUTOCHECK INFO: $1: processor looks good')', `
116                    m4_errprint(`AUTOCHECK ERROR: ====' PROCESSOR_TYPE `$1 =================')
117                    m4_errprint(`AUTOCHECK expected:' defn(`ELEMENTSOF_$1'))
118                    m4_errprint(`AUTOCHECK missing :' defn(`ELEMENTS_UNDONE'))
119                    define(`EXIT_PENDING', 1)
120                ')
121                popdef(`ELEMENTS_UNDONE')
122            ')
123        ')
124
125        popdef(`ELEMENTS_DONE')
126    }
127/* }`}'} */
128    popdef(`FUNC_NAME')
129')
130dnl }}}
131dnl {{{ STRUCT_P_EX(1:type, 2:dst, 3:src, 4:elm-name, 5:name=type, 6:&)
132define(`STRUCT_P_EX', `
133    DBG(`$0($*)')
134    pushdefFUNC_NAME(`$1', `$5')
135    ifdef(`DEFINED_'ifelse(`$5', `', `$1', `$5'), `', `m4_errprint(`AUTOCHECK ERROR: Unknown struct "'ifelse(`$5', `', `$1', `$5')`"')define(`EXIT_PENDING', 1)')
136    assert(sizeof($1) == sizeof(($6 $3)[0]));
137    ifelse(`$6', `', `ALLOC(`$2', `$1')')
138ifdef(`DASM_STRUCT_DIRECT', `', `
139    IFDASM(`do {
140        zval *zv;
141        ALLOC_INIT_ZVAL(zv);
142        array_init(zv);
143    ')
144')
145    FUNC_NAME`'(
146        IFDPRINT( `           $6 $3, indent')
147        IFCALC(   `processor, $6 $3')
148        IFSTORE(  `processor, $6 $2, $6 $3')
149        IFRESTORE(`processor, $6 $2, $6 $3')
150        IFRELOCATE(`
151            ifelse(`$6', `', `DSTPTR_EX(`$1', `$3')', `$6 $3')
152            , ptrdiff
153            , relocatediff
154        ')
155        IFDASM(`dasm, ifdef(`DASM_STRUCT_DIRECT', `DST()', `zv'), $6 $3')
156        TSRMLS_CC
157    );
158ifdef(`DASM_STRUCT_DIRECT', `', `
159    IFDASM(`
160        add_assoc_zval_ex(DST(), XCACHE_STRS("$4"), zv);
161    } while (0);
162    ')
163')
164    popdef(`FUNC_NAME')
165    ifelse(`$6', , `FIXPOINTER_EX(`$1', `$2')')
166')
167dnl }}}
168dnl {{{ STRUCT_P(1:type, 2:elm, 3:name=type)
169define(`STRUCT_P', `
170    DBG(`$0($*)')
171    if (SRC(`$2')) {
172        IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2 ");')
173        STRUCT_P_EX(`$1', `DST(`$2')', `SRC(`$2')', `$2', `$3')
174    }
175    else {
176        IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2:\tNULL\n");')
177        COPYNULL_EX(`DST(`$2')', `$2')
178    }
179    DONE(`$2')
180')
181dnl }}}
182dnl {{{ STRUCT(1:type, 2:elm, 3:name=type)
183define(`STRUCT', `
184    DBG(`$0($*)')
185    assert(sizeof($1) == sizeof(SRC(`$2')));
186    IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2 ");')
187    STRUCT_P_EX(`$1', `DST(`$2')', `SRC(`$2')', `$2', `$3', `&')
188    DONE(`$2')
189')
190dnl }}}
191dnl {{{ STRUCT_ARRAY(1:count_type, 2:count, 3:type, 4:elm, 5:name=type, 6:loopcounter)
192define(`STRUCT_ARRAY', `
193    if (SRC(`$4')) {
194        ifelse(
195            `$6', `', `ifelse(`$1', `', `size_t', `$1') i; pushdef(`LOOPCOUNTER', `i')',
196            `', `', `pushdef(`LOOPCOUNTER', `$6')')
197        pushdefFUNC_NAME(`$3', `$5')
198        IFDASM(`
199            zval *arr;
200            ALLOC_INIT_ZVAL(arr);
201            array_init(arr);
202
203            for (LOOPCOUNTER = 0;
204                    ifelse(`$2', `', `SRC(`$4[LOOPCOUNTER]')',
205                    `', `', `LOOPCOUNTER < SRC(`$2')');
206                    ++LOOPCOUNTER) {
207                zval *zv;
208
209                ALLOC_INIT_ZVAL(zv);
210                array_init(zv);
211                FUNC_NAME (dasm, zv, &(SRC(`$4[LOOPCOUNTER]')) TSRMLS_CC);
212                add_next_index_zval(arr, zv);
213            }
214            add_assoc_zval_ex(DST(), XCACHE_STRS("$4"), arr);
215        ', `
216            dnl find count with NULL
217            ifelse(`$2', `', `
218                size_t count = 0;
219                while (SRC(`$4[count]')) {
220                    ++count;
221                }
222                ++count;
223                pushdef(`ARRAY_ELEMENT_COUNT', `count')
224            ',
225            `', `', `pushdef(`ARRAY_ELEMENT_COUNT', `SRC(`$2')')')
226            ALLOC(`DST(`$4')', `$3', `ARRAY_ELEMENT_COUNT')
227            popdef(`ARRAY_ELEMENT_COUNT')
228
229            for (LOOPCOUNTER = 0;
230                    ifelse(`$2', `', `SRC(`$4[LOOPCOUNTER]')',
231                    `', `', `LOOPCOUNTER < SRC(`$2')');
232                    ++LOOPCOUNTER) {
233                DISABLECHECK(`
234                    pushdef(`ALLOC')
235                    pushdef(`FIXPOINTER_EX')
236                    STRUCT_P_EX(`$3', (DST(`$4') + LOOPCOUNTER), (SRC(`$4') + LOOPCOUNTER), `', `$5')
237                    popdef(`FIXPOINTER_EX')
238                    popdef(`ALLOC')
239                ')
240            }
241            dnl the end marker
242            ifelse(`$2', `', `IFCOPY(`DST(`$4[LOOPCOUNTER]') = NULL;')')
243        ')dnl IFDASM
244        FIXPOINTER(`$3', `$4')
245        DONE(`$4')
246        popdef(`FUNC_NAME')
247        popdef(`LOOPCOUNTER')
248    }
249    else {
250        COPYNULL(`$4')
251    }
252')
253dnl }}}
Note: See TracBrowser for help on using the repository browser.