source: trunk/processor/struct.m4 @ 1440

Last change on this file since 1440 was 1440, checked in by moo, 12 months ago

adds ptrmove

  • Property svn:eol-style set to native
File size: 7.4 KB
Line 
1define(`pushdefFUNC_NAME', `
2    pushdef(`FUNC_NAME', `xc_`'PROCESSOR_TYPE`'_`'ifelse(`$2', `', `$1', `$2')')
3')
4dnl {{{ DECL_STRUCT_P_FUNC(1:type, 2:name, 3:comma=;)
5define(`DECL_STRUCT_P_FUNC', `translit(
6    pushdefFUNC_NAME(`$1', `$2')
7    define(`DEFINED_'ifelse(`$2', `', `$1', `$2'), `')
8    ifdef(`EXPORT_'ifelse(`$2', `', `$1', `$2'), `void', `static void inline')
9    FUNC_NAME`'(
10        IFDPRINT( `const $1 * const src, int indent')
11        IFCALC(   `xc_processor_t *processor, const $1 * const src')
12        IFSTORE(  `xc_processor_t *processor, $1 *dst, const $1 * const src')
13        IFRESTORE(`xc_processor_t *processor, $1 *dst, const $1 * const src')
14        IFPTRMOVE(`const xc_ptrmove_t *ptrmove, $1 * const dst, const $1 * const src')
15        IFDASM(   `xc_dasm_t *dasm, zval *dst, const $1 * const src')
16        TSRMLS_DC
17    )ifelse(`$3', `', `;')
18    popdef(`FUNC_NAME')dnl
19, `
20', ` ')')
21dnl }}}
22dnl {{{ DEF_STRUCT_P_FUNC(1:type, 2:name, 3:body)
23define(`DEF_STRUCT_P_FUNC', `
24    pushdefFUNC_NAME(`$1', `$2')
25/* {`{'{ FUNC_NAME */
26    ifdef(`EXPORT_'ifelse(`$2', `', `$1', `$2'), `
27        /* export: DECL_STRUCT_P_FUNC(`$1', `$2') :export */
28    ')
29DECL_STRUCT_P_FUNC(`$1', `$2', 1)
30    {
31        pushdef(`ELEMENTS_DONE')
32        IFAUTOCHECK(`
33            /* {{{ init assert */
34            ifdef(`SIZEOF_$1', , `m4_errprint(`Warning: missing SIZEOF_$1, safe to ignore')')
35            ifdef(`COUNTOF_$1', , `m4_errprint(`Warning: missing COUNTOF_$1, safe to ignore')')
36            dnl SIZEOF_x COUNTOF_x can be both defined or both not
37            ifdef(`SIZEOF_$1', `
38                ifdef(`COUNTOF_$1', , `m4_errprint(`AUTOCHECK WARN: missing COUNTOF_$1')')
39            ', `
40                define(`SIZEOF_$1', 0)
41            ')
42            ifdef(`COUNTOF_$1', `
43                ifdef(`SIZEOF_$1', , `m4_errprint(`AUTOCHECK WARN: missing SIZEOF_$1')')
44            ', `
45                define(`COUNTOF_$1', 0)
46            ')
47            int xc_autocheck_assert_size = SIZEOF_$1, assert_count = COUNTOF_$1;
48            int xc_autocheck_done_size = 0, xc_autocheck_done_count = 0;
49            ifdef(`ELEMENTSOF_$1', `
50                const char *xc_autocheck_assert_names[] = { ELEMENTSOF_$1 };
51                size_t xc_autocheck_assert_names_count = sizeof(xc_autocheck_assert_names) / sizeof(xc_autocheck_assert_names[0]);
52            ', `
53                const char **xc_autocheck_assert_names = NULL;
54                size_t xc_autocheck_assert_names_count = 0;
55            ')
56            zend_bool xc_autocheck_skip = 0;
57            HashTable xc_autocheck_done_names;
58            zend_hash_init(&xc_autocheck_done_names, 0, NULL, NULL, 0);
59            /* }}} */
60            IFRESTORE(`assert(xc_is_shm(src));')
61            IFCALCSTORE(`assert(!xc_is_shm(src));')
62        ')
63        ifdef(`SIZEOF_$1', , `m4_errprint(`AUTOCHECK WARN: $1: missing structinfo, dont panic')')
64
65        ifdef(`USEMEMCPY', `IFCOPY(`
66            memcpy(dst, src, sizeof($1));
67        ')')
68
69        IFDPRINT(`
70            fprintf(stderr, "%s", "{\n");
71            indent ++;
72        ')
73        {
74            $3`'
75        }
76        IFDPRINT(`
77            indent --;
78            INDENT()fprintf(stderr, "}\n");
79        ')
80
81        IFAUTOCHECK(`
82        /* {{{ autocheck */
83        if (!xc_autocheck_skip) {
84            int name_check_errors = xc_check_names(__FILE__, __LINE__, "FUNC_NAME", xc_autocheck_assert_names, xc_autocheck_assert_names_count, &xc_autocheck_done_names);
85
86            if (xc_autocheck_done_count != assert_count) {
87                fprintf(stderr
88                    , "count assertion failed at %s `#'%d FUNC_NAME`' : unexpected:%d - expecting:%d = %d != 0\n"
89                    , __FILE__, __LINE__
90                    , xc_autocheck_done_count, assert_count, xc_autocheck_done_count - assert_count
91                    );
92            }
93            if (xc_autocheck_done_size != xc_autocheck_assert_size) {
94                fprintf(stderr
95                    , "size assertion failed at %s `#'%d FUNC_NAME`' : unexpected:%d - expecting:%d = %d != 0\n"
96                    , __FILE__, __LINE__
97                    , xc_autocheck_done_size, xc_autocheck_assert_size, xc_autocheck_done_size - xc_autocheck_assert_size
98                    );
99            }
100            if (name_check_errors || xc_autocheck_done_count != assert_count || xc_autocheck_done_size != xc_autocheck_assert_size) {
101                assert(0);
102            }
103        }
104        zend_hash_destroy(&xc_autocheck_done_names);
105        /* }}} */
106        ')
107        ifdef(`AUTOCHECK_SKIP', `undefine(`AUTOCHECK_SKIP')', `
108            ifdef(`ELEMENTSOF_$1', `
109                pushdef(`ELEMENTS_UNDONE', LIST_DIFF(defn(`ELEMENTSOF_$1'), defn(`ELEMENTS_DONE')))
110                ifelse(defn(`ELEMENTS_UNDONE'), , `m4_errprint(`AUTOCHECK INFO: $1: processor looks good')', `
111                    m4_errprint(`AUTOCHECK ERROR: ====' PROCESSOR_TYPE `$1 =================')
112                    m4_errprint(`AUTOCHECK expected:' defn(`ELEMENTSOF_$1'))
113                    m4_errprint(`AUTOCHECK missing :' defn(`ELEMENTS_UNDONE'))
114                    define(`EXIT_PENDING', 1)
115                ')
116                popdef(`ELEMENTS_UNDONE')
117            ')
118        ')
119
120        popdef(`ELEMENTS_DONE')
121    }
122/* }`}'} */
123    popdef(`FUNC_NAME')
124')
125dnl }}}
126dnl {{{ STRUCT_P_EX(1:type, 2:dst, 3:src, 4:elm-name, 5:name=type, 6:&)
127define(`STRUCT_P_EX', `
128    DBG(`$0($*)')
129    pushdefFUNC_NAME(`$1', `$5')
130    ifdef(`DEFINED_'ifelse(`$5', `', `$1', `$5'), `', `m4_errprint(`AUTOCHECK ERROR: Unknown struct "'ifelse(`$5', `', `$1', `$5')`"')define(`EXIT_PENDING', 1)')
131    assert(sizeof($1) == sizeof(($6 $3)[0]));
132    ifelse(`$6', `', `ALLOC(`$2', `$1')')
133ifdef(`DASM_STRUCT_DIRECT', `', `
134    IFDASM(`do {
135        zval *zv;
136        ALLOC_INIT_ZVAL(zv);
137        array_init(zv);
138    ')
139')
140    FUNC_NAME`'(
141        IFDPRINT( `           $6 $3, indent')
142        IFCALC(   `processor, $6 $3')
143        IFSTORE(  `processor, $6 $2, $6 $3')
144        IFRESTORE(`processor, $6 $2, $6 $3')
145        IFPTRMOVE(`
146            ptrmove
147            , ifelse(`$6', `', `DSTPTR_EX(`$1', `$2')', `$6 $2')
148            , ifelse(`$6', `', `SRCPTR_EX(`$1', `$3')', `$6 $3')
149        ')
150        IFDASM(   `dasm, ifdef(`DASM_STRUCT_DIRECT', `dst', `zv'), $6 $3')
151        TSRMLS_CC
152    );
153ifdef(`DASM_STRUCT_DIRECT', `', `
154    IFDASM(`
155        add_assoc_zval_ex(dst, XCACHE_STRS("$4"), zv);
156    } while (0);
157    ')
158')
159    popdef(`FUNC_NAME')
160    ifelse(`$6', , `FIXPOINTER_EX(`$1', `$2', `$3')')
161')
162dnl }}}
163dnl {{{ STRUCT_P(1:type, 2:elm, 3:name=type)
164define(`STRUCT_P', `
165    DBG(`$0($*)')
166    if (SRC(`$2')) {
167        IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2 ");')
168        STRUCT_P_EX(`$1', `DST(`$2')', `SRC(`$2')', `$2', `$3')
169    }
170    else {
171        IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2:\tNULL\n");')
172        COPYNULL_EX(`DST(`$2')', `$2')
173    }
174    DONE(`$2')
175')
176dnl }}}
177dnl {{{ STRUCT(1:type, 2:elm, 3:name=type)
178define(`STRUCT', `
179    DBG(`$0($*)')
180    assert(sizeof($1) == sizeof(SRC(`$2')));
181    IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2 ");')
182    STRUCT_P_EX(`$1', `DST(`$2')', `SRC(`$2')', `$2', `$3', `&')
183    DONE(`$2')
184')
185dnl }}}
186dnl {{{ STRUCT_ARRAY(1:count_type, 2:count, 3:type, 4:elm, 5:name=type, 6:loopcounter)
187define(`STRUCT_ARRAY', `
188    if (SRC(`$4')) {
189        ifelse(
190            `$6', `', `ifelse(`$1', `', `size_t', `$1') i; pushdef(`LOOPCOUNTER', `i')',
191            `', `', `pushdef(`LOOPCOUNTER', `$6')')
192        pushdefFUNC_NAME(`$3', `$5')
193        IFDASM(`
194            zval *arr;
195            ALLOC_INIT_ZVAL(arr);
196            array_init(arr);
197
198            for (LOOPCOUNTER = 0;
199                    ifelse(`$2', `', `SRC(`$4[LOOPCOUNTER]')',
200                    `', `', `LOOPCOUNTER < SRC(`$2')');
201                    ++LOOPCOUNTER) {
202                zval *zv;
203
204                ALLOC_INIT_ZVAL(zv);
205                array_init(zv);
206                FUNC_NAME (dasm, zv, &(SRC(`$4[LOOPCOUNTER]')) TSRMLS_CC);
207                add_next_index_zval(arr, zv);
208            }
209            add_assoc_zval_ex(dst, XCACHE_STRS("$4"), arr);
210        ', `
211            dnl find count with NULL
212            ifelse(`$2', `', `
213                size_t count = 0;
214                while (SRC(`$4[count]')) {
215                    ++count;
216                }
217                ++count;
218                pushdef(`ARRAY_ELEMENT_COUNT', `count')
219            ',
220            `', `', `pushdef(`ARRAY_ELEMENT_COUNT', `SRC(`$2')')')
221            ALLOC(`DST(`$4')', `$3', `ARRAY_ELEMENT_COUNT')
222            popdef(`ARRAY_ELEMENT_COUNT')
223
224            for (LOOPCOUNTER = 0;
225                    ifelse(`$2', `', `SRC(`$4[LOOPCOUNTER]')',
226                    `', `', `LOOPCOUNTER < SRC(`$2')');
227                    ++LOOPCOUNTER) {
228                DISABLECHECK(`
229                    STRUCT(`$3', `$4[LOOPCOUNTER]', `$5')
230                ')
231            }
232            dnl the end marker
233            ifelse(`$2', `', `IFCOPY(`DST(`$4[LOOPCOUNTER]') = NULL;')')
234        ')dnl IFDASM
235        FIXPOINTER(`$3', `$4')
236        DONE(`$4')
237        popdef(`FUNC_NAME')
238        popdef(`LOOPCOUNTER')
239    }
240    else {
241        COPYNULL(`$4')
242    }
243')
244dnl }}}
Note: See TracBrowser for help on using the repository browser.