source: trunk/processor/struct.m4 @ 1416

Last change on this file since 1416 was 1416, checked in by moo, 10 months ago

remove asm from processor, it just cant be implemented in processor

  • Property svn:eol-style set to native
File size: 7.2 KB
Line 
1define(`pushdefFUNC_NAME', `
2    pushdef(`FUNC_NAME', `xc_`'PROCESSOR_TYPE`'_`'ifelse(`$2', `', `$1', `$2')')
3')
4dnl {{{ DECL_STRUCT_P_FUNC(1:type, 2:name, 3:comma=;)
5define(`DECL_STRUCT_P_FUNC', `translit(
6    pushdefFUNC_NAME(`$1', `$2')
7    define(`DEFINED_'ifelse(`$2', `', `$1', `$2'), `')
8    ifdef(`EXPORT_'ifelse(`$2', `', `$1', `$2'), `void', `static void inline')
9    FUNC_NAME`'(
10        IFDPRINT( `const $1 * const src, int indent')
11        IFCALC(   `xc_processor_t *processor, const $1 * const src')
12        IFSTORE(  `xc_processor_t *processor, $1 *dst, const $1 * const src')
13        IFRESTORE(`xc_processor_t *processor, $1 *dst, const $1 * const src')
14        IFDASM(   `xc_dasm_t *dasm, zval *dst, const $1 * const src')
15        TSRMLS_DC
16    )ifelse(`$3', `', `;')
17    popdef(`FUNC_NAME')dnl
18, `
19', ` ')')
20dnl }}}
21dnl {{{ DEF_STRUCT_P_FUNC(1:type, 2:name, 3:body)
22define(`DEF_STRUCT_P_FUNC', `
23    pushdefFUNC_NAME(`$1', `$2')
24/* {`{'{ FUNC_NAME */
25    ifdef(`EXPORT_'ifelse(`$2', `', `$1', `$2'), `
26        /* export: DECL_STRUCT_P_FUNC(`$1', `$2') :export */
27    ')
28DECL_STRUCT_P_FUNC(`$1', `$2', 1)
29    {
30        pushdef(`ELEMENTS_DONE')
31        IFAUTOCHECK(`
32            /* {{{ init assert */
33            ifdef(`SIZEOF_$1', , `m4_errprint(`Warning: missing SIZEOF_$1, safe to ignore')')
34            ifdef(`COUNTOF_$1', , `m4_errprint(`Warning: missing COUNTOF_$1, safe to ignore')')
35            dnl SIZEOF_x COUNTOF_x can be both defined or both not
36            ifdef(`SIZEOF_$1', `
37                ifdef(`COUNTOF_$1', , `m4_errprint(`AUTOCHECK WARN: missing COUNTOF_$1')')
38            ', `
39                define(`SIZEOF_$1', 0)
40            ')
41            ifdef(`COUNTOF_$1', `
42                ifdef(`SIZEOF_$1', , `m4_errprint(`AUTOCHECK WARN: missing SIZEOF_$1')')
43            ', `
44                define(`COUNTOF_$1', 0)
45            ')
46            int xc_autocheck_assert_size = SIZEOF_$1, assert_count = COUNTOF_$1;
47            int xc_autocheck_done_size = 0, xc_autocheck_done_count = 0;
48            ifdef(`ELEMENTSOF_$1', `
49                const char *xc_autocheck_assert_names[] = { ELEMENTSOF_$1 };
50                size_t xc_autocheck_assert_names_count = sizeof(xc_autocheck_assert_names) / sizeof(xc_autocheck_assert_names[0]);
51            ', `
52                const char **xc_autocheck_assert_names = NULL;
53                size_t xc_autocheck_assert_names_count = 0;
54            ')
55            zend_bool xc_autocheck_skip = 0;
56            HashTable xc_autocheck_done_names;
57            zend_hash_init(&xc_autocheck_done_names, 0, NULL, NULL, 0);
58            /* }}} */
59            IFRESTORE(`assert(xc_is_shm(src));')
60            IFCALCSTORE(`assert(!xc_is_shm(src));')
61            do {
62        ')
63        ifdef(`SIZEOF_$1', , `m4_errprint(`AUTOCHECK WARN: $1: missing structinfo, dont panic')')
64
65        ifdef(`USEMEMCPY', `IFCOPY(`
66            memcpy(dst, src, sizeof($1));
67            do {
68        ')')
69
70        IFDPRINT(`
71            fprintf(stderr, "%s", "{\n");
72            indent ++;
73            {
74        ')
75        $3`'
76        IFDPRINT(`
77            }
78            indent --;
79            INDENT()fprintf(stderr, "}\n");
80        ')
81        IFAUTOCHECK(`
82        /* {{{ autocheck */
83        if (!xc_autocheck_skip) {
84            int name_check_errors = xc_check_names(__FILE__, __LINE__, "FUNC_NAME", xc_autocheck_assert_names, xc_autocheck_assert_names_count, &xc_autocheck_done_names);
85
86            if (xc_autocheck_done_count != assert_count) {
87                fprintf(stderr
88                    , "count assertion failed at %s `#'%d FUNC_NAME`' : unexpected:%d - expecting:%d = %d != 0\n"
89                    , __FILE__, __LINE__
90                    , xc_autocheck_done_count, assert_count, xc_autocheck_done_count - assert_count
91                    );
92            }
93            if (xc_autocheck_done_size != xc_autocheck_assert_size) {
94                fprintf(stderr
95                    , "size assertion failed at %s `#'%d FUNC_NAME`' : unexpected:%d - expecting:%d = %d != 0\n"
96                    , __FILE__, __LINE__
97                    , xc_autocheck_done_size, xc_autocheck_assert_size, xc_autocheck_done_size - xc_autocheck_assert_size
98                    );
99            }
100            if (name_check_errors || xc_autocheck_done_count != assert_count || xc_autocheck_done_size != xc_autocheck_assert_size) {
101                assert(0);
102            }
103        }
104        zend_hash_destroy(&xc_autocheck_done_names);
105        /* }}} */
106        ')
107        ifdef(`ELEMENTSOF_$1', `
108            pushdef(`ELEMENTS_UNDONE', LIST_DIFF(defn(`ELEMENTSOF_$1'), defn(`ELEMENTS_DONE')))
109            ifelse(defn(`ELEMENTS_UNDONE'), , `m4_errprint(`AUTOCHECK INFO: $1: processor looks good')', `
110                m4_errprint(`AUTOCHECK ERROR: ====' PROCESSOR_TYPE `$1 =================')
111                m4_errprint(`AUTOCHECK expected:' defn(`ELEMENTSOF_$1'))
112                m4_errprint(`AUTOCHECK missing :' defn(`ELEMENTS_UNDONE'))
113                define(`EXIT_PENDING', 1)
114            ')
115            popdef(`ELEMENTS_UNDONE')
116        ')
117        ifdef(`USEMEMCPY', `IFCOPY(`
118            } while (0);
119        ')')
120        IFAUTOCHECK(`
121            } while (0);
122        ')
123        popdef(`ELEMENTS_DONE')
124    }
125/* }`}'} */
126    popdef(`FUNC_NAME')
127')
128dnl }}}
129dnl {{{ STRUCT_P_EX(1:type, 2:dst, 3:src, 4:elm-name, 5:name=type, 6:&)
130define(`STRUCT_P_EX', `
131    DBG(`$0($*)')
132    pushdefFUNC_NAME(`$1', `$5')
133    ifdef(`DEFINED_'ifelse(`$5', `', `$1', `$5'), `', `m4_errprint(`AUTOCHECK ERROR: Unknown struct "'ifelse(`$5', `', `$1', `$5')`"')define(`EXIT_PENDING', 1)')
134    assert(sizeof($1) == sizeof(($6 $3)[0]));
135    ifelse(`$6', `', `ALLOC(`$2', `$1')')
136ifdef(`DASM_STRUCT_DIRECT', `', `
137    IFDASM(`do {
138        zval *zv;
139        ALLOC_INIT_ZVAL(zv);
140        array_init(zv);
141    ')
142')
143    FUNC_NAME`'(
144        IFDPRINT( `           $6 $3, indent')
145        IFCALC(   `processor, $6 $3')
146        IFSTORE(  `processor, $6 $2, $6 $3')
147        IFRESTORE(`processor, $6 $2, $6 $3')
148        IFDASM(   `dasm, ifdef(`DASM_STRUCT_DIRECT', `dst', `zv'), $6 $3')
149        TSRMLS_CC
150    );
151ifdef(`DASM_STRUCT_DIRECT', `', `
152    IFDASM(`
153        add_assoc_zval_ex(dst, XCACHE_STRS("$4"), zv);
154    } while (0);
155    ')
156')
157    popdef(`FUNC_NAME')
158    ifelse(`$6', , `FIXPOINTER_EX(`$1', `$2')')
159')
160dnl }}}
161dnl {{{ STRUCT_P(1:type, 2:elm, 3:name=type)
162define(`STRUCT_P', `
163    DBG(`$0($*)')
164    if (SRC(`$2')) {
165        IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2 ");')
166        STRUCT_P_EX(`$1', `DST(`$2')', `SRC(`$2')', `$2', `$3')
167    }
168    else {
169        IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2:\tNULL\n");')
170        COPYNULL_EX(`DST(`$2')', `$2')
171    }
172    DONE(`$2')
173')
174dnl }}}
175dnl {{{ STRUCT(1:type, 2:elm, 3:name=type)
176define(`STRUCT', `
177    DBG(`$0($*)')
178    assert(sizeof($1) == sizeof(SRC(`$2')));
179    IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2 ");')
180    STRUCT_P_EX(`$1', `DST(`$2')', `SRC(`$2')', `$2', `$3', `&')
181    DONE(`$2')
182')
183dnl }}}
184dnl {{{ STRUCT_ARRAY(1:count_type, 2:count, 3:type, 4:elm, 5:name=type, 6:loopcounter)
185define(`STRUCT_ARRAY', `
186    if (SRC(`$4')) {
187        ifelse(
188            `$6', `', `ifelse(`$1', `', `size_t', `$1') i; pushdef(`LOOPCOUNTER', `i')',
189            `', `', `pushdef(`LOOPCOUNTER', `$6')')
190        pushdefFUNC_NAME(`$3', `$5')
191        IFDASM(`
192            zval *arr;
193            ALLOC_INIT_ZVAL(arr);
194            array_init(arr);
195
196            for (LOOPCOUNTER = 0;
197                    ifelse(`$2', `', `SRC(`$4[LOOPCOUNTER]')',
198                    `', `', `LOOPCOUNTER < SRC(`$2')');
199                    ++LOOPCOUNTER) {
200                zval *zv;
201
202                ALLOC_INIT_ZVAL(zv);
203                array_init(zv);
204                FUNC_NAME (dasm, zv, &(SRC(`$4[LOOPCOUNTER]')) TSRMLS_CC);
205                add_next_index_zval(arr, zv);
206            }
207            add_assoc_zval_ex(dst, XCACHE_STRS("$4"), arr);
208        ', `
209            dnl find count with NULL
210            ifelse(`$2', `', `
211                size_t count = 0;
212                while (SRC(`$4[count]')) {
213                    ++count;
214                }
215                ++count;
216                pushdef(`ARRAY_ELEMENT_COUNT', `count')
217            ',
218            `', `', `pushdef(`ARRAY_ELEMENT_COUNT', `SRC(`$2')')')
219            ALLOC(`DST(`$4')', `$3', `ARRAY_ELEMENT_COUNT')
220            popdef(`ARRAY_ELEMENT_COUNT')
221
222            for (LOOPCOUNTER = 0;
223                    ifelse(`$2', `', `SRC(`$4[LOOPCOUNTER]')',
224                    `', `', `LOOPCOUNTER < SRC(`$2')');
225                    ++LOOPCOUNTER) {
226                DISABLECHECK(`
227                    STRUCT(`$3', `$4[LOOPCOUNTER]', `$5')
228                ')
229            }
230            dnl the end marker
231            ifelse(`$2', `', `IFCOPY(`DST(`$4[LOOPCOUNTER]') = NULL;')')
232        ')dnl IFDASM
233        FIXPOINTER(`$3', `$4')
234        DONE(`$4')
235        popdef(`FUNC_NAME')
236        popdef(`LOOPCOUNTER')
237    }
238    else {
239        COPYNULL(`$4')
240    }
241')
242dnl }}}
Note: See TracBrowser for help on using the repository browser.