source: trunk/processor/struct.m4 @ 11

Last change on this file since 11 was 11, checked in by moo, 8 years ago

make it build on windows vc compiler

File size: 5.1 KB
Line 
1define(`pushdefFUNC_NAME', `
2    pushdef(`FUNC_NAME', `xc_`'KIND`'_`'ifelse(`$2', `', `$1', `$2')')
3')
4dnl {{{ DECL_STRUCT_P_FUNC(1:type, 2:name, 3:comma=;)
5define(`DECL_STRUCT_P_FUNC', `translit(
6    pushdefFUNC_NAME(`$1', `$2')
7    define(`DEFINED_'ifelse(`$2', `', `$1', `$2'), `')
8    ifdef(`EXPORT_'ifelse(`$2', `', `$1', `$2'), `void', `static void inline')
9    FUNC_NAME`'(
10        IFDPRINT( `const $1 * const src, int indent')
11        IFCALC(   `processor_t *processor, const $1 * const src')
12        IFSTORE(  `processor_t *processor, $1 *dst, const $1 * const src')
13        IFRESTORE(`processor_t *processor, $1 *dst, const $1 * const src')
14        IFDASM(   `zval *dst, const $1 * const src')
15        IFASM(    `$1 *dst, const $1 * const src')
16        TSRMLS_DC
17    )ifelse(`$3', `', `;')
18    popdef(`FUNC_NAME')dnl
19, `
20', ` ')')
21dnl }}}
22dnl {{{ DEF_STRUCT_P_FUNC(1:type, 2:name, 3:body)
23define(`DEF_STRUCT_P_FUNC', `
24    pushdefFUNC_NAME(`$1', `$2')
25/* {`{'{ FUNC_NAME */
26    ifdef(`EXPORT_'ifelse(`$2', `', `$1', `$2'), `
27        /* export: DECL_STRUCT_P_FUNC(`$1', `$2') :export */
28    ')
29DECL_STRUCT_P_FUNC(`$1', `$2', 1)
30    {
31        IFASSERT(`
32            /* {{{ init assert */
33            ifdef(`SIZEOF_$1', , `m4_errprint(`missing SIZEOF_$1, safe to ignore')define(`SIZEOF_$1', 0)')
34            ifdef(`COUNTOF_$1', , `m4_errprint(`missing COUNTOF_$1, safe to ignore')define(`COUNTOF_$1', 0)')
35            int assert_size = SIZEOF_$1, assert_count = COUNTOF_$1;
36            int done_size = 0, done_count = 0;
37            pushdef(`ELEMENTS_DONE')
38            /* }}} */
39            IFRESTORE(`assert(xc_is_shm(src));')
40            IFCALCSTORE(`assert(!xc_is_shm(src));')
41            do {
42        ')
43
44        ifdef(`USEMEMCPY', `IFCOPY(`
45            memcpy(dst, src, sizeof($1));
46            do {
47        ')')
48
49        IFDPRINT(`
50            fprintf(stderr, "%s", " {\n");
51            indent ++;
52        ')
53        $3`'
54        IFDPRINT(`
55            indent --;
56            INDENT()fprintf(stderr, "}\n");
57        ')
58        ifdef(`SKIPASSERT_ONCE', `undefine(`SKIPASSERT_ONCE')', `IFASSERT(`
59                /* {{{ check assert */
60                if (done_count != assert_count) {
61                    fprintf(stderr
62                        , "count assertion failed at %s `#'%d FUNC_NAME`' : unexpected %d - expected %d = %d != 0\n"
63                        , __FILE__, __LINE__
64                        , done_count, assert_count, done_count - assert_count
65                        );
66                    abort();
67                }
68                if (done_size != assert_size) {
69                    fprintf(stderr
70                        , "size assertion failed at %s `#'%d FUNC_NAME`' : %d - %d = %d != 0\n"
71                        , __FILE__, __LINE__
72                        , done_size, assert_size, done_size - assert_size
73                        );
74                    abort();
75                }
76                ifdef(`ELEMENTSOF_$1', `
77                    pushdef(`ELEMENTS_UNDONE', LIST_DIFF(defn(`ELEMENTSOF_$1'), defn(`ELEMENTS_DONE')))
78                    ifelse(defn(`ELEMENTS_UNDONE'), , , `
79                        m4_errprint(`====' KIND `$1 =================')
80                        m4_errprint(`expected:' defn(`ELEMENTSOF_$1'))
81                        m4_errprint(`missing :' defn(`ELEMENTS_UNDONE'))
82                        define(`EXIT_PENDING', 1)
83                    ')
84                    popdef(`ELEMENTS_UNDONE')
85                ')
86                /* }}} */
87        ')')
88        ifdef(`USEMEMCPY', `IFCOPY(`
89            } while (0);
90        ')')
91        IFASSERT(`
92            } while (0);
93            undefine(`ELEMENTS_DONE')
94        ')
95    }
96/* }`}'} */
97    popdef(`FUNC_NAME')
98')
99dnl }}}
100dnl {{{ STRUCT_P_EX(1:type, 2:dst, 3:src, 4:elm-name, 5:name=type, 6:&)
101define(`STRUCT_P_EX', `
102    DBG(`$0($*)')
103    pushdefFUNC_NAME(`$1', `$5')
104    ifdef(`DEFINED_'ifelse(`$5', `', `$1', `$5'), `', `m4_errprint(`Unknown struct "'ifelse(`$5', `', `$1', `$5')`"')')
105    assert(sizeof($1) == sizeof(($6 $3)[0]));
106    ifelse(`$6', `', `ALLOC(`$2', `$1')')
107    IFDASM(`do {
108        zval *zv;
109        ALLOC_INIT_ZVAL(zv);
110        array_init(zv);
111    ')
112    FUNC_NAME`'(
113        IFDPRINT( `           $6 $3, indent')
114        IFCALC(   `processor, $6 $3')
115        IFSTORE(  `processor, $6 $2, $6 $3')
116        IFRESTORE(`processor, $6 $2, $6 $3')
117        IFDASM(   `zv, $6 $3')
118        IFASM(    `$6 $2, $6 $3')
119        TSRMLS_CC
120    );
121    IFDASM(`
122        add_assoc_zval_ex(dst, ZEND_STRS("$4"), zv);
123    } while (0);
124    ')
125    popdef(`FUNC_NAME')
126    ifelse(`$6', , `FIXPOINTER_EX(`$1', `$2')')
127')
128dnl }}}
129dnl {{{ STRUCT_P(1:type, 2:elm, 3:name=type)
130define(`STRUCT_P', `
131    DBG(`$0($*)')
132    if (src->$2) {
133        STRUCT_P_EX(`$1', `dst->$2', `src->$2', `$2', `$3')
134        IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2");')
135    }
136    else {
137        COPYNULL_EX(`dst->$2', `$2')
138        IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2:\tNULL\n");')
139    }
140    DONE(`$2')
141')
142dnl }}}
143dnl {{{ STRUCT(1:type, 2:elm, 3:name=type)
144define(`STRUCT', `
145    DBG(`$0($*)')
146    assert(sizeof($1) == sizeof(src->$2));
147    IFDPRINT(`INDENT()`'fprintf(stderr, "$1:$2");')
148    STRUCT_P_EX(`$1', `dst->$2', `src->$2', `$2', `$3', `&')
149    DONE(`$2')
150')
151dnl }}}
152dnl {{{ STRUCT_ARRAY_I(1:count, 2:type, 3:elm, 4:name=type)
153define(`STRUCT_ARRAY_I', `
154pushdef(`i', `ii')
155STRUCT_ARRAY(`$1', `$2', `$3', `$4')
156popdef(`i')
157')
158dnl }}}
159dnl {{{ STRUCT_ARRAY(1:count, 2:type, 3:elm, 4:name=type)
160define(`STRUCT_ARRAY', `
161    if (src->$3) {
162        pushdefFUNC_NAME(`$2', `$4')
163        IFDASM(`
164            zval *arr;
165            ALLOC_INIT_ZVAL(arr);
166            array_init(arr);
167            for (i = 0; i < src->$1; i ++) {
168                zval *zv;
169
170                ALLOC_INIT_ZVAL(zv);
171                array_init(zv);
172                FUNC_NAME (zv, &(src->$3[i]) TSRMLS_CC);
173                add_next_index_zval(arr, zv);
174            }
175            add_assoc_zval_ex(dst, ZEND_STRS("$3"), arr);
176        ', `
177            ALLOC(`dst->$3', `$2', `src->$1')
178            ifdef(`AFTER_ALLOC', AFTER_ALLOC)
179            for (i = 0; i < src->$1; i ++) {
180                DISABLECHECK(`
181                    ifdef(`BEFORE_LOOP', `BEFORE_LOOP')
182                    STRUCT(`$2', `$3[i]', `$4')
183                ')
184            }
185        ')dnl IFDASM
186        DONE(`$3')
187        popdef(`FUNC_NAME')
188    }
189    else {
190        COPYNULL(`$3')
191        ifdef(`AFTER_ALLOC', AFTER_ALLOC)
192    }
193')
194dnl }}}
Note: See TracBrowser for help on using the repository browser.