source: trunk/processor/process.m4 @ 1372

Last change on this file since 1372 was 1372, checked in by moo, 12 months ago

closes #327: Duplicate ++LOOPCOUNTER

  • Property svn:eol-style set to native
File size: 4.6 KB
Line 
1define(`PROCESS_SCALAR', `dnl {{{ (1:elm, 2:format=%d, 3:type=)
2    IFNOTMEMCPY(`IFCOPY(`DST(`$1') = SRC(`$1');')')
3    IFDPRINT(`
4        INDENT()
5        fprintf(stderr, "$3:$1:\t%ifelse(`$2',`',`d',`$2')\n", SRC(`$1'));
6    ')
7    IFDASM(`
8        ifelse(
9            `$3', `zend_bool', `add_assoc_bool_ex(dst, XCACHE_STRS("$1"), SRC(`$1') ? 1 : 0);'
10        , `', `', `add_assoc_long_ex(dst, XCACHE_STRS("$1"), SRC(`$1'));'
11        )
12    ')
13    DONE(`$1')
14')
15dnl }}}
16define(`PROCESS_xc_ztstring', `dnl {{{ (1:elm)
17    pushdef(`REALPTRTYPE', `zend_class_entry')
18    PROC_STRING(`$1')
19    popdef(`REALPTRTYPE')
20')
21dnl }}}
22define(`PROCESS_xc_zval_type_t', `dnl {{{ (1:elm)
23    IFDPRINT(`
24        INDENT()
25        fprintf(stderr, ":$1:\t%d %s\n", SRC(`$1'), xc_get_data_type(SRC(`$1')));
26        DONE(`$1')
27    ', `PROCESS_SCALAR(`$1')')
28')
29dnl }}}
30define(`PROCESS_xc_op_type', `dnl {{{ (1:elm)
31    IFDPRINT(`
32        INDENT()
33        fprintf(stderr, ":$1:\t%d %s\n", SRC(`$1'), xc_get_op_type(SRC(`$1')));
34        DONE(`$1')
35    ', `PROCESS_SCALAR(`$1')')
36')
37dnl }}}
38define(`PROCESS_xc_opcode', `dnl {{{ (1:elm)
39    IFDPRINT(`
40        INDENT()
41        fprintf(stderr, ":$1:\t%u %s\n", SRC(`$1'), xc_get_opcode(SRC(`$1')));
42        DONE(`$1')
43    ', `PROCESS_SCALAR(`$1')')
44')
45dnl }}}
46define(`PROCESS', `dnl PROCESS(1:type, 2:elm)
47    DBG(`$0($*)')
48    assert(sizeof($1) == sizeof(SRC(`$2')));
49    ifelse(
50        `$1', `zend_bool',        `PROCESS_SCALAR(`$2', `u',  `$1')'
51    , `$1', `zend_uchar',       `PROCESS_SCALAR(`$2', `u',  `$1')'
52    , `$1', `char',             `PROCESS_SCALAR(`$2', `d',  `$1')'
53    , `$1', `int32_t',          `PROCESS_SCALAR(`$2', `d',  `$1')'
54    , `$1', `unsigned char',    `PROCESS_SCALAR(`$2', `u',  `$1')'
55    , `$1', `zend_uint',        `PROCESS_SCALAR(`$2', `u',  `$1')'
56    , `$1', `uint',             `PROCESS_SCALAR(`$2', `u',  `$1')'
57    , `$1', `unsigned int',     `PROCESS_SCALAR(`$2', `u',  `$1')'
58    , `$1', `zend_ulong',       `PROCESS_SCALAR(`$2', `lu', `$1')'
59    , `$1', `ulong',            `PROCESS_SCALAR(`$2', `lu', `$1')'
60    , `$1', `size_t',           `PROCESS_SCALAR(`$2', `lu', `$1')'
61    , `$1', `long',             `PROCESS_SCALAR(`$2', `ld', `$1')'
62    , `$1', `time_t',           `PROCESS_SCALAR(`$2', `ld', `$1')'
63    , `$1', `zend_ushort',      `PROCESS_SCALAR(`$2', `hu', `$1')'
64    , `$1', `int',              `PROCESS_SCALAR(`$2', `d',  `$1')'
65    , `$1', `double',           `PROCESS_SCALAR(`$2', `f',  `$1')'
66    , `$1', `xc_entry_type_t',  `PROCESS_SCALAR(`$2', `d',  `$1')'
67    , `$1', `xc_hash_value_t',  `PROCESS_SCALAR(`$2', `lu', `$1')'
68    , `$1', `last_brk_cont_t',  `PROCESS_SCALAR(`$2', `d', `$1')'
69
70    , `$1', `xc_ztstring',       `PROCESS_xc_ztstring(`$2')'
71    , `$1', `xc_zval_type_t',    `PROCESS_xc_zval_type_t(`$2')'
72    , `$1', `xc_op_type',        `PROCESS_xc_op_type(`$2')'
73    , `$1', `xc_opcode',         `PROCESS_xc_opcode(`$2')'
74    , `$1', `opcode_handler_t',  `/* is copying enough? */COPY(`$2')'
75    , `$1', `xc_md5sum_t',       `COPY(`$2')'
76    , `', `', `m4_errprint(`AUTOCHECK ERROR: Unknown type "$1"')define(`EXIT_PENDING', 1)'
77    )
78')
79define(`PROCESS_ARRAY', `dnl {{{ (1:count, 2:type, 3:elm, [4:real_type])
80    if (src->$3) {
81        int LOOPCOUNTER;
82        IFDASM(`
83            zval *arr;
84            ALLOC_INIT_ZVAL(arr);
85            array_init(arr);
86
87            for (LOOPCOUNTER = 0;
88                    ifelse(`$1', `', `src->$3[LOOPCOUNTER]',
89                    `', `', `LOOPCOUNTER < SRC(`$1')');
90                    ++LOOPCOUNTER) {
91                pushdef(`dst', `arr')
92                pushdef(`SRC', `ifelse(`$4', `', `', `', `', `($2)')' defn(`SRC') `[LOOPCOUNTER]')
93                popdef(`add_assoc_bool_ex', `add_next_index_bool($1, $3)')
94                popdef(`add_assoc_string_ex', `add_next_index_string($1, $3)')
95                popdef(`add_assoc_long_ex', `add_next_index_long($1, $3)')
96                popdef(`add_assoc_zval_ex', `add_next_index_zval($1, $3)')
97                DISABLECHECK(`
98                    PROCESS(`$2', `$3')
99                ')
100                popdef(`add_assoc_zval_ex')
101                popdef(`add_assoc_long_ex')
102                popdef(`add_assoc_string_ex')
103                popdef(`add_assoc_bool_ex')
104                popdef(`SRC')
105                popdef(`dst')
106            }
107            add_assoc_zval_ex(dst, XCACHE_STRS("$3"), arr);
108        ', `
109            dnl find count with NULL
110            ifelse(`$1', `', `
111                size_t count = 0;
112                while (SRC(`$3[count]')) {
113                    ++count;
114                }
115                ++count;
116                pushdef(`STRUCT_COUNT', `count')
117            ',
118            `', `', `pushdef(`STRUCT_COUNT', `SRC(`$1')')')
119            ALLOC(`dst->$3', `$2', `STRUCT_COUNT', , `$4')
120            popdef(`STRUCT_COUNT')
121
122            for (LOOPCOUNTER = 0;
123                    ifelse(`$1', `', `src->$3[LOOPCOUNTER]',
124                    `', `', `LOOPCOUNTER < SRC(`$1')');
125                    ++LOOPCOUNTER) {
126                DISABLECHECK(`
127                    pushdef(`DST', defn(`DST') `[LOOPCOUNTER]')
128                    pushdef(`SRC', `ifelse(`$4', `', `', `', `', `($2)')' defn(`SRC') `[LOOPCOUNTER]')
129                    PROCESS(`$2', `$3')
130                    popdef(`SRC')
131                    popdef(`DST')
132                ')
133            }
134            dnl the end marker
135            ifelse(`$1', `', `IFCOPY(`DST(`$3[LOOPCOUNTER]') = NULL;')')
136        ')dnl IFDASM
137        DONE(`$3')
138    }
139    else {
140        COPYNULL(`$3')
141    }
142')
143dnl }}}
Note: See TracBrowser for help on using the repository browser.