source: trunk/processor/main.m4 @ 690

Last change on this file since 690 was 690, checked in by moo, 4 years ago

fix build by avoing nested macro with ifdef

  • Property svn:eol-style set to native
File size: 8.9 KB
Line 
1divert(-1)
2dnl ================ start ======================
3dnl define(`XCACHE_ENABLE_TEST')
4dnl define(`DEBUG_SIZE')
5define(`USEMEMCPY')
6
7dnl ================ main
8
9dnl {{{ basic
10define(`REDEF', `ifdef(`$1', `undefine(`$1')') define(`$1', `$2')')
11define(`MAKE_MACRONAME', `translit(`$1', ` ():
12', `_____')')
13define(`ONCE', `ifdef(MAKE_MACRONAME(`ONCE $1'), `', `define(MAKE_MACRONAME(`ONCE $1'))$1')')
14define(`m4_errprint', `ONCE(`errprint(`$1
15')')')
16ifdef(`len', `
17define(`m4_len', defn(`len'))
18undefine(`len')
19')
20define(`ZEND_STRS', `($1), (sizeof($1))')
21define(`ZEND_STRL', `($1), (sizeof($1) - 1)')
22dnl ============
23define(`INDENT', `xc_dprint_indent(indent);')
24dnl }}}
25dnl {{{ ALLOC(1:dst, 2:type, 3:count=1, 4:clean=false, 5:forcetype=$2)
26define(`ALLOC', `
27    pushdef(`COUNT', `ifelse(`$3', `', `1', `$3')')
28    pushdef(`SIZE', `sizeof($2)ifelse(`$3', `', `', ` * $3')')
29    pushdef(`FORCETYPE', `ifelse(`$5', , `$2', `$5')')
30    /* allocate */
31    IFCALC(`
32        IFASSERT(`
33            xc_stack_push(&processor->allocsizes, (void *) (long) (SIZE));
34            xc_stack_push(&processor->allocsizes, (void *) (long) (__LINE__));
35        ')
36        processor->size = (size_t) ALIGN(processor->size);
37        processor->size += SIZE;
38    ')
39    IFSTORE(`
40        IFASSERT(`{
41            if (!xc_stack_count(&processor->allocsizes)) {
42                fprintf(stderr, "mismatch `$@' at line %d\n", __LINE__);
43            }
44            else {
45                unsigned long expect = (unsigned long) xc_stack_pop(&processor->allocsizes);
46                unsigned long atline = (unsigned long) xc_stack_pop(&processor->allocsizes);
47                unsigned long real = SIZE;
48                if (expect != real) {
49                    fprintf(stderr, "mismatch `$@' at line %d(was %lu): real %lu - expect %lu = %lu\n", __LINE__, atline, real, expect, real - expect);
50                }
51            }
52        }')
53        ifdef(`DEBUG_SIZE', ` {
54            void *oldp = processor->p;
55        ')
56        $1 = (FORCETYPE *) (processor->p = (char *) ALIGN(processor->p));
57        ifelse(`$4', `', `
58                IFASSERT(`memset($1, -1, SIZE);')
59            ', `
60                memset($1, 0, SIZE);
61        ')
62        processor->p += SIZE;
63
64        ifdef(`DEBUG_SIZE', `
65            xc_totalsize += (char *) processor->p - (char *) oldp;
66            fprintf(stderr, "%d\t%d\t`'SIZE()\n", (char *) processor->p - (char *) oldp, xc_totalsize);
67        }
68        ')
69    ')
70    IFRESTORE(`ifelse(`$4', `', `
71            ifelse(
72                FORCETYPE*COUNT, `zval*1', `ALLOC_ZVAL($1);',
73                FORCETYPE*COUNT, `HashTable*1', `ALLOC_HASHTABLE($1);',
74                `', `', `$1 = (FORCETYPE *) emalloc(SIZE);')
75            IFASSERT(`memset($1, -1, SIZE);')
76        ', `
77            $1 = (FORCETYPE *) ecalloc(COUNT, sizeof($2));
78        ')
79    ')
80    popdef(`COUNT')
81    popdef(`SIZE')
82')
83dnl CALLOC(1:dst, 2:type [, 3:count=1 ])
84define(`CALLOC', `ALLOC(`$1', `$2', `$3', `1')')
85dnl }}}
86dnl {{{ PROC_INT(1:elm, 2:format=%d, 3:type=, 4:spec=)
87define(`PROC_INT', `
88    IFNOTMEMCPY(`IFCOPY(`dst->$1 = src->$1;')')
89    IFDPRINT(`
90        INDENT()
91        ifelse(
92            `$3 $1', `zval_data_type type', `fprintf(stderr, "$3:$1:\t%d %s\n", src->$1, xc_get_data_type(src->$1));'
93        , `$3 $1', `int op_type', `fprintf(stderr, "$3:$1:\t%d %s\n", src->$1, xc_get_op_type(src->$1));'
94        , `$3 $1', `zend_uchar opcode', `fprintf(stderr, "$3:$1:\t%d %s\n", src->$1, xc_get_opcode(src->$1));'
95        , `', `', `fprintf(stderr, "$3:$1:\t%ifelse(`$2',`',`d',`$2')\n", src->$1);')
96    ')
97    IFDASM(`
98        ifelse(
99            `$3', `zend_bool', `add_assoc_bool_ex(dst, ZEND_STRS("$1"), src->$1 ? 1 : 0);'
100        , `', `', `add_assoc_long_ex(dst, ZEND_STRS("$1"), src->$1);'
101        )
102    ')
103    DONE(`$1')
104')
105dnl }}}
106dnl {{{ PROC_CLASS_ENTRY_P(1:elm)
107define(`PROC_CLASS_ENTRY_P', `PROC_CLASS_ENTRY_P_EX(`dst->$1', `src->$1', `$1')`'DONE(`$1')')
108dnl PROC_CLASS_ENTRY_P_EX(1:dst, 2:src, 3:elm-name)
109define(`PROC_CLASS_ENTRY_P_EX', `
110    if ($2) {
111        IFSTORE(`$1 = (zend_class_entry *) xc_get_class_num(processor, $2);')
112        IFRESTORE(`$1 = xc_get_class(processor, (zend_ulong) $2);')
113#ifdef IS_UNICODE
114        IFDASM(`add_assoc_unicodel_ex(dst, ZEND_STRS("$3"), ZSTR_U($2->name), $2->name_length, 1);')
115#else
116        IFDASM(`add_assoc_stringl_ex(dst, ZEND_STRS("$3"), $2->name, $2->name_length, 1);')
117#endif
118    }
119    else {
120        COPYNULL_EX(`$1', `$3')
121    }
122')
123dnl }}}
124dnl {{{ IFASSERTEX
125define(`IFASSERTEX', `ifdef(`XCACHE_ENABLE_TEST', `$1', `$2')')
126dnl }}}
127dnl {{{ IFASSERT
128define(`IFASSERT', `IFASSERTEX(`
129#ifndef NDEBUG
130        $1
131#endif
132')')
133dnl }}}
134dnl {{{ DBG
135define(`DBG', `ifdef(`XCACHE_ENABLE_TEST', `
136    /* `$1' */
137')')
138dnl }}}
139dnl {{{ EXPORT
140define(`EXPORT', `define(`EXPORT_$1')')
141dnl }}}
142dnl {{{ FIXPOINTER
143define(`FIXPOINTER', `FIXPOINTER_EX(`$1', `dst->$2')')
144define(`FIXPOINTER_EX', `IFSTORE(`
145    $2 = ($1 *) processor->cache->shm->handlers->to_readonly(processor->cache->shm, (char *)$2);
146')')
147define(`UNFIXPOINTER', `UNFIXPOINTER_EX(`$1', `dst->$2')')
148define(`UNFIXPOINTER_EX', `IFSTORE(`
149    $2 = ($1 *) processor->cache->shm->handlers->to_readwrite(processor->cache->shm, (char *)$2);
150')')
151dnl }}}
152dnl {{{ COPY
153define(`COPY', `IFNOTMEMCPY(`IFCOPY(`dst->$1 = src->$1;')')DONE(`$1')')
154dnl }}}
155dnl {{{ COPY_N_EX
156define(`COPY_N_EX', `
157    ALLOC(`dst->$3', `$2', `src->$1')
158    IFCOPY(`
159        memcpy(dst->$3, src->$3, sizeof(dst->$3[0]) * src->$1);
160        ')
161')
162dnl }}}
163dnl {{{ COPY_N
164define(`COPY_N', `COPY_N_EX(`$1',`$2')DONE(`$1')')
165dnl }}}
166dnl {{{ COPYPOINTER
167define(`COPYPOINTER', `COPY(`$1')')
168dnl }}}
169dnl {{{ COPYARRAY_EX
170define(`COPYARRAY_EX', `IFNOTMEMCPY(`IFCOPY(`memcpy(dst->$1, src->$1, sizeof(dst->$1));')')')
171dnl }}}
172dnl {{{ COPYARRAY
173define(`COPYARRAY', `COPYARRAY_EX(`$1',`$2')DONE(`$1')')
174dnl }}}
175dnl {{{ SETNULL_EX
176define(`SETNULL_EX', `IFCOPY(`$1 = NULL;')')
177define(`SETNULL', `SETNULL_EX(`dst->$1')DONE(`$1')')
178dnl }}}
179dnl {{{ COPYNULL_EX(1:dst, 2:elm-name)
180define(`COPYNULL_EX', `
181    IFDASM(`add_assoc_null_ex(dst, ZEND_STRS("$2"));')
182    IFNOTMEMCPY(`IFCOPY(`$1 = NULL;')')
183')
184dnl }}}
185dnl {{{ COPYNULL(1:elm)
186# foreach(VAR, (LIST), STMT)
187m4_define([foreach],
188       [m4_pushdef([$1])_foreach([$1], [$2], [$3])m4_popdef([$1])])
189m4_define([_arg1], [$1])
190m4_define([_foreach],
191       [ifelse([$2], [()], ,
192       [m4_define([$1], _arg1$2)$3[]_foreach([$1],
193                                                       (shift$2),
194                                                       [$3])])])
195define(`COPYNULL', `
196    COPYNULL_EX(`dst->$1', `$2')DONE(`$1')
197')
198dnl }}}
199dnl {{{ LIST_DIFF(1:left-list, 2:right-list)
200define(`foreach',
201       `pushdef(`$1')_foreach(`$1', `$2', `$3')popdef(`$1')')
202define(`_arg1', `$1')
203define(`_foreach',                             
204       `ifelse(`$2', `()', ,                       
205       `define(`$1', _arg1$2)$3`'_foreach(`$1',
206                                                       (shift$2),
207                                                       `$3')')')
208define(`LIST_DIFF', `dnl
209foreach(`i', `($1)', `pushdef(`item_'defn(`i'))')dnl allocate variable for items in $1
210foreach(`i', `($2)', `pushdef(`item_'defn(`i'))undefine(`item_'defn(`i'))')dnl allocate variable for items in $2, and undefine it
211foreach(`i', `($1)', `ifdef(`item_'defn(`i'), `defn(`i') ')')dnl see what is still defined
212foreach(`i', `($2)', `define(`item_'defn(`i'))popdef(`item_'defn(`i'))')dnl
213foreach(`i', `($1)', `popdef(`item_'defn(`i'))')dnl
214')
215dnl }}}
216dnl {{{ DONE_*
217define(`DONE_SIZE', `IFASSERT(`
218    done_size += $1`';
219    done_count ++;
220')')
221define(`DONE', `
222    define(`ELEMENTS_DONE', defn(`ELEMENTS_DONE')`,$1')
223    DONE_SIZE(`sizeof(src->$1)')
224')
225define(`DISABLECHECK', `
226    pushdef(`DONE_SIZE')
227    pushdef(`DONE')
228$1
229    popdef(`DONE_SIZE')
230    popdef(`DONE')
231')
232dnl }}}
233dnl {{{ IF**
234define(`IFCALC', `ifelse(KIND, `calc', `$1', `$2')')
235define(`IFSTORE', `ifelse(KIND, `store', `$1', `$2')')
236define(`IFCALCSTORE', `IFSTORE(`$1', `IFCALC(`$1', `$2')')')
237define(`IFRESTORE', `ifelse(KIND, `restore', `$1', `$2')')
238define(`IFCOPY', `IFSTORE(`$1', `IFRESTORE(`$1', `$2')')')
239define(`IFCALCCOPY', `IFCALC(`$1', `IFCOPY(`$1', `$2')')')
240define(`IFDPRINT', `ifelse(KIND, `dprint', `$1', `$2')')
241define(`IFASM', `ifelse(KIND, `asm', `$1', `$2')')
242define(`IFDASM', `ifelse(KIND, `dasm', `$1', `$2')')
243dnl }}}
244EXPORT(`zend_op')
245EXPORT(`zend_op_array')
246EXPORT(`zend_function')
247EXPORT(`HashTable_zend_function')
248EXPORT(`zend_class_entry')
249EXPORT(`xc_classinfo_t')
250EXPORT(`xc_funcinfo_t')
251EXPORT(`xc_entry_t')
252EXPORT(`xc_entry_data_php_t')
253EXPORT(`zval')
254
255include(srcdir`/processor/hashtable.m4')
256include(srcdir`/processor/string.m4')
257include(srcdir`/processor/struct.m4')
258include(srcdir`/processor/dispatch.m4')
259include(srcdir`/processor/head.m4')
260
261define(`IFNOTMEMCPY', `ifdef(`USEMEMCPY', `', `$1')')
262REDEF(`KIND', `calc') include(srcdir`/processor/processor.m4')
263pushdef(`xc_get_class_num', ``xc_get_class_num'($@)')
264REDEF(`KIND', `store') include(srcdir`/processor/processor.m4')
265popdef(`xc_get_class_num')
266pushdef(`xc_get_class', ``xc_get_class'($@)')
267REDEF(`KIND', `restore') include(srcdir`/processor/processor.m4')
268popdef(`xc_get_class')
269
270REDEF(`IFNOTMEMCPY', `$1')
271#ifdef HAVE_XCACHE_DPRINT
272REDEF(`KIND', `dprint') include(srcdir`/processor/processor.m4')
273#endif /* HAVE_XCACHE_DPRINT */
274#ifdef HAVE_XCACHE_DISASSEMBLER
275REDEF(`KIND', `dasm') include(srcdir`/processor/processor.m4')
276#endif /* HAVE_XCACHE_DISASSEMBLER */
277#ifdef HAVE_XCACHE_ASSEMBLER
278REDEF(`KIND', `asm') include(srcdir`/processor/processor.m4')
279#endif /* HAVE_XCACHE_ASSEMBLER */
280
281ifdef(`EXIT_PENDING', `m4exit(EXIT_PENDING)')
Note: See TracBrowser for help on using the repository browser.