source: trunk/processor/main.m4 @ 1461

Last change on this file since 1461 was 1461, checked in by moo, 13 months ago

relocate: update dst/src to compile

  • Property svn:eol-style set to native
File size: 8.9 KB
Line 
1divert(-1)
2dnl ================ start ======================
3dnl define(`XCACHE_ENABLE_TEST')
4dnl define(`DEBUG_SIZE')
5define(`USEMEMCPY')
6
7dnl ================ main
8
9dnl {{{ basic
10define(`REDEF', `ifdef(`$1', `undefine(`$1')') define(`$1', `$2')')
11define(`MAKE_MACRONAME', `translit(`$1', ` ():
12', `_____')')
13define(`ONCE', `ifdef(MAKE_MACRONAME(`ONCE $1'), `', `define(MAKE_MACRONAME(`ONCE $1'))$1')')
14define(`m4_errprint', `ONCE(`errprint(`$1
15')')')
16ifdef(`len', `
17define(`m4_len', defn(`len'))
18undefine(`len')
19')
20define(`XCACHE_STRS', `($1), (sizeof($1))')
21define(`XCACHE_STRL', `($1), (sizeof($1) - 1)')
22define(`SRC', `ifelse(`$1', `', `src', `src->$1')')
23define(`DST', `ifelse(`$1', `', `dst', `dst->$1')')
24dnl ============
25define(`INDENT', `xc_dprint_indent(indent);')
26dnl }}}
27dnl {{{ SRCPTR_EX(1:type, 2:elm)
28define(`SRCPTR_EX', `DSTPTR_EX(`$1', `$2')')
29dnl }}}
30dnl {{{ DSTPTR_EX(1:type, 2:elm)
31define(`DSTPTR_EX', `$2')
32dnl }}}
33dnl {{{ ALLOC(1:dst, 2:type, 3:count=1, 4:clean=false, 5:realtype=$2)
34define(`ALLOC', `
35    pushdef(`COUNT', `ifelse(`$3', `', `1', `$3')')
36    pushdef(`SIZE', `sizeof($2)ifelse(`$3', `', `', ` * $3')')
37    pushdef(`REALTYPE', `ifelse(`$5', , `$2', `$5')')
38    /* allocate */
39    IFCALC(`
40        IFAUTOCHECK(`
41            xc_stack_push(&processor->allocsizes, (void *) (long) (SIZE));
42            xc_stack_push(&processor->allocsizes, (void *) (long) (__LINE__));
43        ')
44        processor->size = (size_t) ALIGN(processor->size);
45        processor->size += SIZE;
46    ')
47    IFSTORE(`
48        IFAUTOCHECK(`{
49            if (!xc_stack_count(&processor->allocsizes)) {
50                fprintf(stderr, "mismatch `$@' at line %d\n", __LINE__);
51            }
52            else {
53                unsigned long expect = (unsigned long) xc_stack_pop(&processor->allocsizes);
54                unsigned long atline = (unsigned long) xc_stack_pop(&processor->allocsizes);
55                unsigned long real = SIZE;
56                if (expect != real) {
57                    fprintf(stderr, "mismatch `$@' at line %d(was %lu): real %lu - expect %lu = %lu\n", __LINE__, atline, real, expect, real - expect);
58                }
59            }
60        }')
61        ifdef(`DEBUG_SIZE', ` {
62            void *oldp = processor->p;
63        ')
64        $1 = (REALTYPE *) (processor->p = (char *) ALIGN(processor->p));
65        ifelse(`$4', `', `
66                IFAUTOCHECK(`memsetptr($1, (void *) (unsigned long) __LINE__, SIZE);')
67            ', `
68                memset($1, 0, SIZE);
69        ')
70        processor->p += SIZE;
71
72        ifdef(`DEBUG_SIZE', `
73            xc_totalsize += (char *) processor->p - (char *) oldp;
74            fprintf(stderr, "%d\t%d\t`'SIZE()\n", (char *) processor->p - (char *) oldp, xc_totalsize);
75        }
76        ')
77    ')
78    IFRESTORE(`ifelse(`$4', `', `
79            ifelse(
80                REALTYPE*COUNT, `zval*1', `ALLOC_ZVAL($1);',
81                REALTYPE*COUNT, `HashTable*1', `ALLOC_HASHTABLE($1);',
82                `', `', `$1 = (REALTYPE *) emalloc(SIZE);')
83            IFAUTOCHECK(`memsetptr($1, (void *) __LINE__, SIZE);')
84        ', `
85            $1 = (REALTYPE *) ecalloc(COUNT, sizeof($2));
86        ')
87    ')
88    popdef(`REALTYPE')
89    popdef(`COUNT')
90    popdef(`SIZE')
91')
92dnl CALLOC(1:dst, 2:type [, 3:count=1, 4:realtype=$2 ])
93define(`CALLOC', `ALLOC(`$1', `$2', `$3', `1', `$4')')
94dnl }}}
95dnl {{{ PROC_CLASS_ENTRY_P(1:elm)
96define(`PROC_CLASS_ENTRY_P', `PROC_CLASS_ENTRY_P_EX(`DST(`$1')', `SRC(`$1')', `$1')`'DONE(`$1')')
97dnl PROC_CLASS_ENTRY_P_EX(1:dst, 2:src, 3:elm-name)
98define(`PROC_CLASS_ENTRY_P_EX', `
99    if ($2) {
100        IFSTORE(`$1 = (zend_class_entry *) xc_get_class_num(processor, $2);')
101        IFRESTORE(`$1 = xc_get_class(processor, (zend_ulong) $2);')
102#ifdef IS_UNICODE
103        IFDASM(`add_assoc_unicodel_ex(DST(), XCACHE_STRS("$3"), ZSTR_U($2->name), $2->name_length, 1);')
104#else
105        IFDASM(`add_assoc_stringl_ex(DST(), XCACHE_STRS("$3"), (char *) $2->name, $2->name_length, 1);')
106#endif
107    }
108    else {
109        COPYNULL_EX(`$1', `$3')
110    }
111')
112dnl }}}
113dnl {{{ IFAUTOCHECKEX
114define(`IFAUTOCHECKEX', `ifdef(`XCACHE_ENABLE_TEST', `$1', `$2')')
115dnl }}}
116dnl {{{ IFAUTOCHECK
117define(`IFAUTOCHECK', `IFAUTOCHECKEX(`
118#ifndef NDEBUG
119        $1
120#endif
121')')
122dnl }}}
123dnl {{{ DBG
124define(`DBG', `ifdef(`XCACHE_ENABLE_TEST', `
125    /* `$1' */
126')')
127dnl }}}
128dnl {{{ EXPORT(1:code)
129define(`EXPORT', `/* export: $1 :export */')
130define(`EXPORTED', `EXPORT(`$1')
131$1')
132define(`EXPORTED_FUNCTION', `EXPORT(`$1;')
133$1')
134dnl }}}
135dnl {{{ EXPORT_PROCESSOR(1:type, 2:processor)
136define(`EXPORT_PROCESSOR', `define(`EXPORT_$1_$2', 1)')
137dnl }}}
138dnl {{{ FIXPOINTER(1:type, 2:ele)
139define(`FIXPOINTER', `FIXPOINTER_EX(`$1', `DST(`$2')')')
140dnl }}}
141dnl {{{ FIXPOINTER_EX(1:type, 2:dst)
142define(`FIXPOINTER_EX', `')
143dnl }}}
144dnl {{{ IFNOTMEMCPY
145define(`IFNOTMEMCPY', `ifdef(`USEMEMCPY', `', `$1')')
146dnl }}}
147dnl {{{ COPY
148define(`COPY', `IFNOTMEMCPY(`IFCOPY(`DST(`$1') = SRC(`$1');')')DONE(`$1')')
149dnl }}}
150dnl {{{ COPY_N_EX(1:count, 2:type, 3:dst)
151define(`COPY_N_EX', `
152    ALLOC(`DST(`$3')', `$2', `SRC(`$1')')
153    IFCOPY(`
154        memcpy(DST(`$3'), SRC(`$3'), sizeof(DST(`$3[0]')) * SRC(`$1'));
155        ')
156')
157dnl }}}
158dnl {{{ COPYPOINTER
159define(`COPYPOINTER', `COPY(`$1')')
160dnl }}}
161dnl {{{ SETNULL_EX
162define(`SETNULL_EX', `IFCOPY(`$1 = NULL;')')
163define(`SETNULL', `SETNULL_EX(`DST(`$1')')DONE(`$1')')
164dnl }}}
165dnl {{{ COPYNULL_EX(1:dst, 2:elm-name)
166define(`COPYNULL_EX', `
167    IFDASM(`add_assoc_null_ex(DST(), XCACHE_STRS("$2"));')
168    IFNOTMEMCPY(`IFCOPY(`$1 = NULL;')')
169    assert(patsubst($1, DST(), SRC()) == NULL);
170')
171dnl }}}
172dnl {{{ COPYNULL(1:elm)
173define(`COPYNULL', `
174    COPYNULL_EX(`DST(`$1')', `$1')DONE(`$1')
175')
176dnl }}}
177dnl {{{ COPYZERO_EX(1:dst, 2:elm-name)
178define(`COPYZERO_EX', `
179    IFDASM(`add_assoc_long_ex(DST(), XCACHE_STRS("$2"), 0);')
180    IFNOTMEMCPY(`IFCOPY(`$1 = 0;')')
181    assert(patsubst($1, DST(), SRC()) == 0);
182')
183dnl }}}
184dnl {{{ COPYZERO(1:elm)
185define(`COPYZERO', `
186    COPYZERO_EX(`DST(`$1')', `$1')DONE(`$1')
187')
188dnl }}}
189dnl {{{ LIST_DIFF(1:left-list, 2:right-list)
190define(`foreach',
191       `pushdef(`$1')_foreach(`$1', `$2', `$3')popdef(`$1')')
192define(`_arg1', `$1')
193define(`_foreach',                             
194       `ifelse(`$2', `()', ,                       
195       `define(`$1', _arg1$2)$3`'_foreach(`$1',
196                                                       (shift$2),
197                                                       `$3')')')
198define(`LIST_DIFF', `dnl
199foreach(`i', `($1)', `pushdef(`item_'defn(`i'))')dnl allocate variable for items in $1
200foreach(`i', `($2)', `pushdef(`item_'defn(`i'))undefine(`item_'defn(`i'))')dnl allocate variable for items in $2, and undefine it
201foreach(`i', `($1)', `ifdef(`item_'defn(`i'), `defn(`i') ')')dnl see what is still defined
202foreach(`i', `($2)', `define(`item_'defn(`i'))popdef(`item_'defn(`i'))')dnl
203foreach(`i', `($1)', `popdef(`item_'defn(`i'))')dnl
204')
205dnl }}}
206dnl {{{ DONE_*
207define(`DONE_SIZE', `IFAUTOCHECK(`dnl
208    xc_autocheck_done_size += (int) $1`';
209    xc_autocheck_done_count ++;
210')')
211define(`DONE', `
212    define(`ELEMENTS_DONE', defn(`ELEMENTS_DONE')`,"$1"')
213    IFAUTOCHECK(`dnl
214        if (zend_u_hash_exists(&xc_autocheck_done_names, IS_STRING, "$1", sizeof("$1"))) {
215            fprintf(stderr
216                , "duplicate field at %s `#'%d FUNC_NAME`' : %s\n"
217                , __FILE__, __LINE__
218                , "$1"
219                );
220        }
221        else {
222            zend_uchar b = 1;
223            zend_hash_add(&xc_autocheck_done_names, "$1", sizeof("$1"), (void*)&b, sizeof(b), NULL);
224        }
225    ')
226    DONE_SIZE(`sizeof(SRC(`$1'))')
227')
228define(`DISABLECHECK', `
229    pushdef(`DONE_SIZE')
230    pushdef(`DONE')
231$1
232    popdef(`DONE_SIZE')
233    popdef(`DONE')
234')
235dnl }}}
236dnl {{{ IF**
237define(`IFCALC', `ifelse(PROCESSOR_TYPE, `calc', `$1', `$2')')
238define(`IFSTORE', `ifelse(PROCESSOR_TYPE, `store', `$1', `$2')')
239define(`IFCALCSTORE', `IFSTORE(`$1', `IFCALC(`$1', `$2')')')
240define(`IFRESTORE', `ifelse(PROCESSOR_TYPE, `restore', `$1', `$2')')
241define(`IFCOPY', `IFSTORE(`$1', `IFRESTORE(`$1', `$2')')')
242define(`IFCALCCOPY', `IFCALC(`$1', `IFCOPY(`$1', `$2')')')
243define(`IFRELOCATE', `ifelse(PROCESSOR_TYPE, `relocate', `$1', `$2')')
244define(`IFFIXPOINTER', `IFSTORE(`$1', `IFRELOCATE(`$1', `$2')')')
245define(`IFDPRINT', `ifelse(PROCESSOR_TYPE, `dprint', `$1', `$2')')
246define(`IFDASM', `ifelse(PROCESSOR_TYPE, `dasm', `$1', `$2')')
247dnl }}}
248
249EXPORT_PROCESSOR(`dasm',   `zend_op_array')
250EXPORT_PROCESSOR(`dasm',   `zend_function')
251EXPORT_PROCESSOR(`dasm',   `zend_class_entry')
252EXPORT_PROCESSOR(`dprint', `zval')
253
254include(srcdir`/processor/hashtable.m4')
255include(srcdir`/processor/string.m4')
256include(srcdir`/processor/struct.m4')
257include(srcdir`/processor/process.m4')
258include(srcdir`/processor/head.m4')
259
260REDEF(`PROCESSOR_TYPE', `calc') include(srcdir`/processor/processor.m4')
261
262pushdef(`FIXPOINTER_EX', `$2 = ($1 *) processor->shm->handlers->to_readonly(processor->shm, (void *)$2);')
263REDEF(`PROCESSOR_TYPE', `store') include(srcdir`/processor/processor.m4')
264popdef(`FIXPOINTER_EX')
265
266REDEF(`PROCESSOR_TYPE', `restore') include(srcdir`/processor/processor.m4')
267
268pushdef(`DSTPTR_EX', `ptradd($1 *, notnullable($2), ptrdiff)')
269pushdef(`FIXPOINTER_EX', `$2 = ptradd($1 *, notnullable($2), relocatediff);')
270pushdef(`SRC', defn(`DST'))
271REDEF(`PROCESSOR_TYPE', `relocate') include(srcdir`/processor/processor.m4')
272popdef(`SRC')
273popdef(`FIXPOINTER_EX')
274popdef(`DSTPTR_EX')
275
276#ifdef HAVE_XCACHE_DPRINT
277REDEF(`PROCESSOR_TYPE', `dprint') include(srcdir`/processor/processor.m4')
278#endif /* HAVE_XCACHE_DPRINT */
279#ifdef HAVE_XCACHE_DISASSEMBLER
280REDEF(`PROCESSOR_TYPE', `dasm') include(srcdir`/processor/processor.m4')
281#endif /* HAVE_XCACHE_DISASSEMBLER */
282
283include(srcdir`/processor/foot.m4')
284
285ifdef(`EXIT_PENDING', `m4exit(EXIT_PENDING)')
Note: See TracBrowser for help on using the repository browser.