source: trunk/processor/main.m4 @ 1449

Last change on this file since 1449 was 1449, checked in by moo, 13 months ago

remove unused export

  • Property svn:eol-style set to native
File size: 8.7 KB
Line 
1divert(-1)
2dnl ================ start ======================
3dnl define(`XCACHE_ENABLE_TEST')
4dnl define(`DEBUG_SIZE')
5define(`USEMEMCPY')
6
7dnl ================ main
8
9dnl {{{ basic
10define(`REDEF', `ifdef(`$1', `undefine(`$1')') define(`$1', `$2')')
11define(`MAKE_MACRONAME', `translit(`$1', ` ():
12', `_____')')
13define(`ONCE', `ifdef(MAKE_MACRONAME(`ONCE $1'), `', `define(MAKE_MACRONAME(`ONCE $1'))$1')')
14define(`m4_errprint', `ONCE(`errprint(`$1
15')')')
16ifdef(`len', `
17define(`m4_len', defn(`len'))
18undefine(`len')
19')
20define(`XCACHE_STRS', `($1), (sizeof($1))')
21define(`XCACHE_STRL', `($1), (sizeof($1) - 1)')
22define(`DST', `dst->$1')
23define(`SRC', `src->$1')
24dnl ============
25define(`INDENT', `xc_dprint_indent(indent);')
26dnl }}}
27dnl {{{ SRCPTR_EX(1:type, 2:elm)
28define(`SRCPTR_EX', `IFRELOCATE(`(($1 *) (((char *) $2) + ptrdiff))', `$2')')
29dnl }}}
30dnl {{{ ALLOC(1:dst, 2:type, 3:count=1, 4:clean=false, 5:realtype=$2)
31define(`ALLOC', `
32    pushdef(`COUNT', `ifelse(`$3', `', `1', `$3')')
33    pushdef(`SIZE', `sizeof($2)ifelse(`$3', `', `', ` * $3')')
34    pushdef(`REALTYPE', `ifelse(`$5', , `$2', `$5')')
35    /* allocate */
36    IFCALC(`
37        IFAUTOCHECK(`
38            xc_stack_push(&processor->allocsizes, (void *) (long) (SIZE));
39            xc_stack_push(&processor->allocsizes, (void *) (long) (__LINE__));
40        ')
41        processor->size = (size_t) ALIGN(processor->size);
42        processor->size += SIZE;
43    ')
44    IFSTORE(`
45        IFAUTOCHECK(`{
46            if (!xc_stack_count(&processor->allocsizes)) {
47                fprintf(stderr, "mismatch `$@' at line %d\n", __LINE__);
48            }
49            else {
50                unsigned long expect = (unsigned long) xc_stack_pop(&processor->allocsizes);
51                unsigned long atline = (unsigned long) xc_stack_pop(&processor->allocsizes);
52                unsigned long real = SIZE;
53                if (expect != real) {
54                    fprintf(stderr, "mismatch `$@' at line %d(was %lu): real %lu - expect %lu = %lu\n", __LINE__, atline, real, expect, real - expect);
55                }
56            }
57        }')
58        ifdef(`DEBUG_SIZE', ` {
59            void *oldp = processor->p;
60        ')
61        $1 = (REALTYPE *) (processor->p = (char *) ALIGN(processor->p));
62        ifelse(`$4', `', `
63                IFAUTOCHECK(`memsetptr($1, (void *) (unsigned long) __LINE__, SIZE);')
64            ', `
65                memset($1, 0, SIZE);
66        ')
67        processor->p += SIZE;
68
69        ifdef(`DEBUG_SIZE', `
70            xc_totalsize += (char *) processor->p - (char *) oldp;
71            fprintf(stderr, "%d\t%d\t`'SIZE()\n", (char *) processor->p - (char *) oldp, xc_totalsize);
72        }
73        ')
74    ')
75    IFRESTORE(`ifelse(`$4', `', `
76            ifelse(
77                REALTYPE*COUNT, `zval*1', `ALLOC_ZVAL($1);',
78                REALTYPE*COUNT, `HashTable*1', `ALLOC_HASHTABLE($1);',
79                `', `', `$1 = (REALTYPE *) emalloc(SIZE);')
80            IFAUTOCHECK(`memsetptr($1, (void *) __LINE__, SIZE);')
81        ', `
82            $1 = (REALTYPE *) ecalloc(COUNT, sizeof($2));
83        ')
84    ')
85    popdef(`REALTYPE')
86    popdef(`COUNT')
87    popdef(`SIZE')
88')
89dnl CALLOC(1:dst, 2:type [, 3:count=1, 4:realtype=$2 ])
90define(`CALLOC', `ALLOC(`$1', `$2', `$3', `1', `$4')')
91dnl }}}
92dnl {{{ PROC_CLASS_ENTRY_P(1:elm)
93define(`PROC_CLASS_ENTRY_P', `PROC_CLASS_ENTRY_P_EX(`DST(`$1')', `SRC(`$1')', `$1')`'DONE(`$1')')
94dnl PROC_CLASS_ENTRY_P_EX(1:dst, 2:src, 3:elm-name)
95define(`PROC_CLASS_ENTRY_P_EX', `
96    if ($2) {
97        IFSTORE(`$1 = (zend_class_entry *) xc_get_class_num(processor, $2);')
98        IFRESTORE(`$1 = xc_get_class(processor, (zend_ulong) $2);')
99#ifdef IS_UNICODE
100        IFDASM(`add_assoc_unicodel_ex(dst, XCACHE_STRS("$3"), ZSTR_U($2->name), $2->name_length, 1);')
101#else
102        IFDASM(`add_assoc_stringl_ex(dst, XCACHE_STRS("$3"), (char *) $2->name, $2->name_length, 1);')
103#endif
104    }
105    else {
106        COPYNULL_EX(`$1', `$3')
107    }
108')
109dnl }}}
110dnl {{{ IFAUTOCHECKEX
111define(`IFAUTOCHECKEX', `ifdef(`XCACHE_ENABLE_TEST', `$1', `$2')')
112dnl }}}
113dnl {{{ IFAUTOCHECK
114define(`IFAUTOCHECK', `IFAUTOCHECKEX(`
115#ifndef NDEBUG
116        $1
117#endif
118')')
119dnl }}}
120dnl {{{ DBG
121define(`DBG', `ifdef(`XCACHE_ENABLE_TEST', `
122    /* `$1' */
123')')
124dnl }}}
125dnl {{{ EXPORT(1:code)
126define(`EXPORT', `/* export: $1 :export */')
127define(`EXPORTED', `EXPORT(`$1')
128$1')
129define(`EXPORTED_FUNCTION', `EXPORT(`$1;')
130$1')
131dnl }}}
132dnl {{{ EXPORT_PROCESSOR(1:type, 2:processor)
133define(`EXPORT_PROCESSOR', `define(`EXPORT_$1_$2', 1)')
134dnl }}}
135dnl {{{ FIXPOINTER(1:type, 2:ele)
136define(`FIXPOINTER', `FIXPOINTER_EX(`$1', `DST(`$2')')')
137dnl }}}
138dnl {{{ FIXPOINTER_EX(1:type, 2:dst)
139define(`FIXPOINTER_EX', `
140    IFSTORE(`$2 = ($1 *) processor->shm->handlers->to_readonly(processor->shm, (void *)$2);')
141    IFRELOCATE(`
142        pushdef(`relocatee', `patsubst($2, `dst', `src')')
143        relocatee = ($1 *) (((char *) relocatee) + relocatediff);
144        popdef(`relocatee')
145    ')
146')
147dnl }}}
148dnl {{{ IFNOTMEMCPY
149define(`IFNOTMEMCPY', `ifdef(`USEMEMCPY', `', `$1')')
150dnl }}}
151dnl {{{ COPY
152define(`COPY', `IFNOTMEMCPY(`IFCOPY(`DST(`$1') = SRC(`$1');')')DONE(`$1')')
153dnl }}}
154dnl {{{ COPY_N_EX(1:count, 2:type, 3:dst)
155define(`COPY_N_EX', `
156    ALLOC(`DST(`$3')', `$2', `SRC(`$1')')
157    IFCOPY(`
158        memcpy(DST(`$3'), SRC(`$3'), sizeof(DST(`$3[0]')) * SRC(`$1'));
159        ')
160')
161dnl }}}
162dnl {{{ COPYPOINTER
163define(`COPYPOINTER', `COPY(`$1')')
164dnl }}}
165dnl {{{ SETNULL_EX
166define(`SETNULL_EX', `IFCOPY(`$1 = NULL;')')
167define(`SETNULL', `SETNULL_EX(`DST(`$1')')DONE(`$1')')
168dnl }}}
169dnl {{{ COPYNULL_EX(1:dst, 2:elm-name)
170define(`COPYNULL_EX', `
171    IFDASM(`add_assoc_null_ex(dst, XCACHE_STRS("$2"));')
172    IFNOTMEMCPY(`IFCOPY(`$1 = NULL;')')
173    assert(patsubst($1, dst, src) == NULL);
174')
175dnl }}}
176dnl {{{ COPYNULL(1:elm)
177define(`COPYNULL', `
178    COPYNULL_EX(`DST(`$1')', `$1')DONE(`$1')
179')
180dnl }}}
181dnl {{{ COPYZERO_EX(1:dst, 2:elm-name)
182define(`COPYZERO_EX', `
183    IFDASM(`add_assoc_long_ex(dst, XCACHE_STRS("$2"), 0);')
184    IFNOTMEMCPY(`IFCOPY(`$1 = 0;')')
185    assert(patsubst($1, dst, src) == 0);
186')
187dnl }}}
188dnl {{{ COPYZERO(1:elm)
189define(`COPYZERO', `
190    COPYZERO_EX(`DST(`$1')', `$1')DONE(`$1')
191')
192dnl }}}
193dnl {{{ LIST_DIFF(1:left-list, 2:right-list)
194define(`foreach',
195       `pushdef(`$1')_foreach(`$1', `$2', `$3')popdef(`$1')')
196define(`_arg1', `$1')
197define(`_foreach',                             
198       `ifelse(`$2', `()', ,                       
199       `define(`$1', _arg1$2)$3`'_foreach(`$1',
200                                                       (shift$2),
201                                                       `$3')')')
202define(`LIST_DIFF', `dnl
203foreach(`i', `($1)', `pushdef(`item_'defn(`i'))')dnl allocate variable for items in $1
204foreach(`i', `($2)', `pushdef(`item_'defn(`i'))undefine(`item_'defn(`i'))')dnl allocate variable for items in $2, and undefine it
205foreach(`i', `($1)', `ifdef(`item_'defn(`i'), `defn(`i') ')')dnl see what is still defined
206foreach(`i', `($2)', `define(`item_'defn(`i'))popdef(`item_'defn(`i'))')dnl
207foreach(`i', `($1)', `popdef(`item_'defn(`i'))')dnl
208')
209dnl }}}
210dnl {{{ DONE_*
211define(`DONE_SIZE', `IFAUTOCHECK(`dnl
212    xc_autocheck_done_size += (int) $1`';
213    xc_autocheck_done_count ++;
214')')
215define(`DONE', `
216    define(`ELEMENTS_DONE', defn(`ELEMENTS_DONE')`,"$1"')
217    IFAUTOCHECK(`dnl
218        if (zend_u_hash_exists(&xc_autocheck_done_names, IS_STRING, "$1", sizeof("$1"))) {
219            fprintf(stderr
220                , "duplicate field at %s `#'%d FUNC_NAME`' : %s\n"
221                , __FILE__, __LINE__
222                , "$1"
223                );
224        }
225        else {
226            zend_uchar b = 1;
227            zend_hash_add(&xc_autocheck_done_names, "$1", sizeof("$1"), (void*)&b, sizeof(b), NULL);
228        }
229    ')
230    DONE_SIZE(`sizeof(SRC(`$1'))')
231')
232define(`DISABLECHECK', `
233    pushdef(`DONE_SIZE')
234    pushdef(`DONE')
235$1
236    popdef(`DONE_SIZE')
237    popdef(`DONE')
238')
239dnl }}}
240dnl {{{ IF**
241define(`IFCALC', `ifelse(PROCESSOR_TYPE, `calc', `$1', `$2')')
242define(`IFSTORE', `ifelse(PROCESSOR_TYPE, `store', `$1', `$2')')
243define(`IFCALCSTORE', `IFSTORE(`$1', `IFCALC(`$1', `$2')')')
244define(`IFRESTORE', `ifelse(PROCESSOR_TYPE, `restore', `$1', `$2')')
245define(`IFRELOCATE', `ifelse(PROCESSOR_TYPE, `relocate', `$1', `$2')')
246define(`IFCOPY', `IFSTORE(`$1', `IFRESTORE(`$1', `$2')')')
247define(`IFCALCCOPY', `IFCALC(`$1', `IFCOPY(`$1', `$2')')')
248define(`IFDPRINT', `ifelse(PROCESSOR_TYPE, `dprint', `$1', `$2')')
249define(`IFDASM', `ifelse(PROCESSOR_TYPE, `dasm', `$1', `$2')')
250dnl }}}
251
252EXPORT_PROCESSOR(`dasm', `zend_op_array')
253EXPORT_PROCESSOR(`dasm', `zend_function')
254EXPORT_PROCESSOR(`dasm', `zend_class_entry')
255EXPORT_PROCESSOR(`dprint',  `zval')
256
257include(srcdir`/processor/hashtable.m4')
258include(srcdir`/processor/string.m4')
259include(srcdir`/processor/struct.m4')
260include(srcdir`/processor/process.m4')
261include(srcdir`/processor/head.m4')
262
263REDEF(`PROCESSOR_TYPE', `calc') include(srcdir`/processor/processor.m4')
264REDEF(`PROCESSOR_TYPE', `store') include(srcdir`/processor/processor.m4')
265REDEF(`PROCESSOR_TYPE', `restore') include(srcdir`/processor/processor.m4')
266REDEF(`PROCESSOR_TYPE', `relocate') include(srcdir`/processor/processor.m4')
267
268#ifdef HAVE_XCACHE_DPRINT
269REDEF(`PROCESSOR_TYPE', `dprint') include(srcdir`/processor/processor.m4')
270#endif /* HAVE_XCACHE_DPRINT */
271#ifdef HAVE_XCACHE_DISASSEMBLER
272REDEF(`PROCESSOR_TYPE', `dasm') include(srcdir`/processor/processor.m4')
273#endif /* HAVE_XCACHE_DISASSEMBLER */
274
275include(srcdir`/processor/foot.m4')
276
277ifdef(`EXIT_PENDING', `m4exit(EXIT_PENDING)')
Note: See TracBrowser for help on using the repository browser.