source: svn/trunk/config.m4 @ 30

Last change on this file since 30 was 30, checked in by Xuefer, 11 years ago

use mkstructinfo no matter if test is enabled, but ignore the awk error

File size: 3.0 KB
Line 
1dnl vim:ts=2:sw=2:expandtab
2
3AC_DEFUN([XCACHE_OPTION], [
4  PHP_ARG_ENABLE(xcache-$1, for XCache $1,
5  [  --enable-xcache-$2    XCache: $4], no, no)
6  if test "$PHP_$3" != "no"; then
7    xcache_sources="$xcache_sources $1.c"
8    XCACHE_MODULES="$XCACHE_MODULES $1"
9    HAVE_$3=1
10    AC_DEFINE([HAVE_$3], 1, [Define for XCache: $4])
11  else
12    HAVE_$3=
13  fi
14])dnl
15
16PHP_ARG_ENABLE(xcache, for XCache support,
17[  --enable-xcache         Include XCache support.])
18
19if test "$PHP_XCACHE" != "no"; then
20  xcache_sources="processor.c \
21                  xcache.c \
22                  mmap.c \
23                  mem.c \
24                  const_string.c \
25                  opcode_spec.c \
26                  stack.c \
27                  utils.c \
28                  lock.c \
29                  "
30  XCACHE_MODULES="cacher"
31  XCACHE_OPTION([optimizer],    [optimizer   ], [XCACHE_OPTIMIZER],    [(N/A)])
32  XCACHE_OPTION([coverager],    [coverager   ], [XCACHE_COVERAGER],    [Enable code coverage dumper, NOT for production server])
33  XCACHE_OPTION([assembler],    [assembler   ], [XCACHE_ASSEMBLER],    [(N/A)])
34  XCACHE_OPTION([disassembler], [disassembler], [XCACHE_DISASSEMBLER], [Enable opcode to php variable dumper, NOT for production server])
35  XCACHE_OPTION([encoder],      [encoder     ], [XCACHE_ENCODER],      [(N/A)])
36  XCACHE_OPTION([decoder],      [decoder     ], [XCACHE_DECODER],      [(N/A)])
37  AC_DEFINE_UNQUOTED([XCACHE_MODULES], "$XCACHE_MODULES", [Define what modules is built with XCache])
38
39  PHP_NEW_EXTENSION(xcache, $xcache_sources, $ext_shared)
40  PHP_ADD_MAKEFILE_FRAGMENT()
41
42  PHP_ARG_ENABLE(xcache-test, for XCache self test,
43  [  --enable-xcache-test            XCache: Enable self test - FOR DEVELOPERS ONLY!!], no, no)
44  if test "$PHP_XCACHE_TEST" != "no"; then
45    XCACHE_ENABLE_TEST=-DXCACHE_ENABLE_TEST
46    AC_DEFINE([HAVE_XCACHE_TEST], 1, [Define to enable XCache self test])
47  else
48    XCACHE_ENABLE_TEST=
49  fi
50  PHP_SUBST([XCACHE_ENABLE_TEST])
51
52  AC_PATH_PROGS([AWK], [gawk awk])
53  PHP_SUBST([AWK])
54  AC_PATH_PROGS([M4], [m4])
55  PHP_SUBST([M4])
56  AC_PATH_PROGS([GREP], [grep])
57  PHP_SUBST([GREP])
58  AC_PATH_PROGS([SED], [sed])
59  PHP_SUBST([SED])
60
61  AC_PATH_PROGS([INDENT], [indent cat])
62  case $INDENT in
63  */indent[)]
64    XCACHE_INDENT="$INDENT -kr --use-tabs --tab-size 4 -sob -nce"
65    ;;
66  *[)]
67    XCACHE_INDENT=cat
68    ;;
69  esac
70  PHP_SUBST([XCACHE_INDENT])
71
72  dnl $ac_srcdir etc require PHP_NEW_EXTENSION
73  XCACHE_PROC_SOURCES=`ls $ac_srcdir/processor/*.m4`
74  PHP_SUBST([XCACHE_PROC_SOURCES])
75
76  AC_MSG_CHECKING(if you have opcode_spec_def.h for XCache)
77  if test -e "$ac_srcdir/opcode_spec_def.h" ; then
78    AC_DEFINE([HAVE_XCACHE_OPCODE_SPEC_DEF], 1, [Define if you have opcode_spec_def.h for XCache])
79    AC_MSG_RESULT(yes)
80  else
81    dnl check for features depend on opcode_spec_def.h
82    AC_MSG_RESULT(no)
83    define([ERROR], [
84      AC_MSG_ERROR([cannot build with $1, $ac_srcdir/opcode_spec_def.h required])
85    ])
86    if test "$PHP_XCACHE_DISASSEMBLER" != "no" ; then
87      ERROR(disassembler)
88    fi
89    undefine([ERROR])
90  fi
91fi
Note: See TracBrowser for help on using the repository browser.