source: branches/1.3/processor/main.m4 @ 817

Last change on this file since 817 was 817, checked in by moo, 4 years ago

merge from trunk: disassembler/decompiler improvements

  • Property svn:eol-style set to native
File size: 8.2 KB
Line 
1divert(-1)
2dnl ================ start ======================
3dnl define(`XCACHE_ENABLE_TEST')
4dnl define(`DEBUG_SIZE')
5define(`USEMEMCPY')
6
7dnl ================ main
8
9dnl {{{ basic
10define(`REDEF', `ifdef(`$1', `undefine(`$1')') define(`$1', `$2')')
11define(`MAKE_MACRONAME', `translit(`$1', ` ():
12', `_____')')
13define(`ONCE', `ifdef(MAKE_MACRONAME(`ONCE $1'), `', `define(MAKE_MACRONAME(`ONCE $1'))$1')')
14define(`m4_errprint', `ONCE(`errprint(`$1
15')')')
16ifdef(`len', `
17define(`m4_len', defn(`len'))
18undefine(`len')
19')
20define(`ZEND_STRS', `($1), (sizeof($1))')
21define(`ZEND_STRL', `($1), (sizeof($1) - 1)')
22dnl ============
23define(`INDENT', `xc_dprint_indent(indent);')
24dnl }}}
25dnl {{{ ALLOC(1:dst, 2:type, 3:count=1, 4:clean=false, 5:forcetype=$2)
26define(`ALLOC', `
27    pushdef(`COUNT', `ifelse(`$3', `', `1', `$3')')
28    pushdef(`SIZE', `sizeof($2)ifelse(`$3', `', `', ` * $3')')
29    pushdef(`FORCETYPE', `ifelse(`$5', , `$2', `$5')')
30    /* allocate */
31    IFCALC(`
32        IFASSERT(`
33            xc_stack_push(&processor->allocsizes, (void *) (long) (SIZE));
34            xc_stack_push(&processor->allocsizes, (void *) (long) (__LINE__));
35        ')
36        processor->size = (size_t) ALIGN(processor->size);
37        processor->size += SIZE;
38    ')
39    IFSTORE(`
40        IFASSERT(`{
41            if (!xc_stack_count(&processor->allocsizes)) {
42                fprintf(stderr, "mismatch `$@' at line %d\n", __LINE__);
43            }
44            else {
45                unsigned long expect = (unsigned long) xc_stack_pop(&processor->allocsizes);
46                unsigned long atline = (unsigned long) xc_stack_pop(&processor->allocsizes);
47                unsigned long real = SIZE;
48                if (expect != real) {
49                    fprintf(stderr, "mismatch `$@' at line %d(was %lu): real %lu - expect %lu = %lu\n", __LINE__, atline, real, expect, real - expect);
50                }
51            }
52        }')
53        ifdef(`DEBUG_SIZE', ` {
54            void *oldp = processor->p;
55        ')
56        $1 = (FORCETYPE *) (processor->p = (char *) ALIGN(processor->p));
57        ifelse(`$4', `', `
58                IFASSERT(`memset($1, -1, SIZE);')
59            ', `
60                memset($1, 0, SIZE);
61        ')
62        processor->p += SIZE;
63
64        ifdef(`DEBUG_SIZE', `
65            xc_totalsize += (char *) processor->p - (char *) oldp;
66            fprintf(stderr, "%d\t%d\t`'SIZE()\n", (char *) processor->p - (char *) oldp, xc_totalsize);
67        }
68        ')
69    ')
70    IFRESTORE(`ifelse(`$4', `', `
71            ifelse(
72                FORCETYPE*COUNT, `zval*1', `ALLOC_ZVAL($1);',
73                FORCETYPE*COUNT, `HashTable*1', `ALLOC_HASHTABLE($1);',
74                `', `', `$1 = (FORCETYPE *) emalloc(SIZE);')
75            IFASSERT(`memset($1, -1, SIZE);')
76        ', `
77            $1 = (FORCETYPE *) ecalloc(COUNT, sizeof($2));
78        ')
79    ')
80    popdef(`COUNT')
81    popdef(`SIZE')
82')
83dnl CALLOC(1:dst, 2:type [, 3:count=1 ])
84define(`CALLOC', `ALLOC(`$1', `$2', `$3', `1')')
85dnl }}}
86dnl {{{ PROC_INT(1:elm, 2:format=%d, 3:type=, 4:spec=)
87define(`PROC_INT', `
88    IFNOTMEMCPY(`IFCOPY(`dst->$1 = src->$1;')')
89    IFDPRINT(`
90        INDENT()
91        ifelse(
92            `$3 $1', `zval_data_type type', `fprintf(stderr, "$3:$1:\t%d %s\n", src->$1, xc_get_data_type(src->$1));'
93        , `$3 $1', `int op_type', `fprintf(stderr, "$3:$1:\t%d %s\n", src->$1, xc_get_op_type(src->$1));'
94        , `$3 $1', `zend_uchar opcode', `fprintf(stderr, "$3:$1:\t%d %s\n", src->$1, xc_get_opcode(src->$1));'
95        , `', `', `fprintf(stderr, "$3:$1:\t%ifelse(`$2',`',`d',`$2')\n", src->$1);')
96    ')
97    IFDASM(`
98        ifelse(
99            `$3', `zend_bool', `add_assoc_bool_ex(dst, ZEND_STRS("$1"), src->$1 ? 1 : 0);'
100        , `', `', `add_assoc_long_ex(dst, ZEND_STRS("$1"), src->$1);'
101        )
102    ')
103    DONE(`$1')
104')
105dnl }}}
106dnl {{{ PROC_CLASS_ENTRY_P(1:elm)
107define(`PROC_CLASS_ENTRY_P', `PROC_CLASS_ENTRY_P_EX(`dst->$1', `src->$1', `$1')`'DONE(`$1')')
108dnl PROC_CLASS_ENTRY_P_EX(1:dst, 2:src, 3:elm-name)
109define(`PROC_CLASS_ENTRY_P_EX', `
110    if ($2) {
111        IFSTORE(`$1 = (zend_class_entry *) xc_get_class_num(processor, $2);')
112        IFRESTORE(`$1 = xc_get_class(processor, (zend_ulong) $2);')
113#ifdef IS_UNICODE
114        IFDASM(`add_assoc_unicodel_ex(dst, ZEND_STRS("$3"), ZSTR_U($2->name), $2->name_length, 1);')
115#else
116        IFDASM(`add_assoc_stringl_ex(dst, ZEND_STRS("$3"), $2->name, $2->name_length, 1);')
117#endif
118    }
119    else {
120        COPYNULL_EX(`$1', `$3')
121    }
122')
123dnl }}}
124dnl {{{ IFASSERTEX
125define(`IFASSERTEX', `ifdef(`XCACHE_ENABLE_TEST', `$1', `$2')')
126dnl }}}
127dnl {{{ IFASSERT
128define(`IFASSERT', `IFASSERTEX(`
129#ifndef NDEBUG
130        $1
131#endif
132')')
133dnl }}}
134dnl {{{ DBG
135define(`DBG', `ifdef(`XCACHE_ENABLE_TEST', `
136    /* `$1' */
137')')
138dnl }}}
139dnl {{{ EXPORT
140define(`EXPORT', `define(`EXPORT_$1')')
141dnl }}}
142dnl {{{ FIXPOINTER
143define(`FIXPOINTER', `FIXPOINTER_EX(`$1', `dst->$2')')
144define(`FIXPOINTER_EX', `IFSTORE(`
145    $2 = ($1 *) processor->xce_src->cache->shm->handlers->to_readonly(processor->xce_src->cache->shm, (char *)$2);
146')')
147define(`UNFIXPOINTER', `UNFIXPOINTER_EX(`$1', `dst->$2')')
148define(`UNFIXPOINTER_EX', `IFSTORE(`
149    $2 = ($1 *) processor->xce_src->cache->shm->handlers->to_readwrite(processor->xce_src->cache->shm, (char *)$2);
150')')
151dnl }}}
152dnl {{{ COPY
153define(`COPY', `IFNOTMEMCPY(`IFCOPY(`dst->$1 = src->$1;')')DONE(`$1')')
154dnl }}}
155dnl {{{ SETNULL_EX
156define(`SETNULL_EX', `IFCOPY(`$1 = NULL;')')
157define(`SETNULL', `SETNULL_EX(`dst->$1')DONE(`$1')')
158dnl }}}
159dnl {{{ COPYNULL_EX(1:dst, 2:elm-name)
160define(`COPYNULL_EX', `
161    IFDASM(`add_assoc_null_ex(dst, ZEND_STRS("$2"));')
162    IFNOTMEMCPY(`IFCOPY(`$1 = NULL;')')
163')
164dnl }}}
165dnl {{{ COPYNULL(1:elm)
166define(`COPYNULL', `
167    COPYNULL_EX(`dst->$1', `$1')DONE(`$1')
168')
169dnl }}}
170dnl {{{ LIST_DIFF(1:left-list, 2:right-list)
171define(`foreach',
172       `pushdef(`$1')_foreach(`$1', `$2', `$3')popdef(`$1')')
173define(`_arg1', `$1')
174define(`_foreach',                             
175       `ifelse(`$2', `()', ,                       
176       `define(`$1', _arg1$2)$3`'_foreach(`$1',
177                                                       (shift$2),
178                                                       `$3')')')
179define(`LIST_DIFF', `dnl
180foreach(`i', `($1)', `pushdef(`item_'defn(`i'))')dnl allocate variable for items in $1
181foreach(`i', `($2)', `pushdef(`item_'defn(`i'))undefine(`item_'defn(`i'))')dnl allocate variable for items in $2, and undefine it
182foreach(`i', `($1)', `ifdef(`item_'defn(`i'), `defn(`i') ')')dnl see what is still defined
183foreach(`i', `($2)', `define(`item_'defn(`i'))popdef(`item_'defn(`i'))')dnl
184foreach(`i', `($1)', `popdef(`item_'defn(`i'))')dnl
185')
186dnl }}}
187dnl {{{ DONE_*
188define(`DONE_SIZE', `IFASSERT(`dnl
189    done_size += $1`';
190    done_count ++;
191')')
192define(`DONE', `
193    define(`ELEMENTS_DONE', defn(`ELEMENTS_DONE')`,"$1"')
194    IFASSERT(`dnl
195        if (zend_hash_exists(&done_names, "$1", sizeof("$1"))) {
196            fprintf(stderr
197                , "duplicate field at %s `#'%d FUNC_NAME`' : %s\n"
198                , __FILE__, __LINE__
199                , "$1"
200                );
201        }
202        else {
203            zend_uchar b = 1;
204            zend_hash_add(&done_names, "$1", sizeof("$1"), (void*)&b, sizeof(b), NULL);
205        }
206    ')
207    DONE_SIZE(`sizeof(src->$1)')
208')
209define(`DISABLECHECK', `
210    pushdef(`DONE_SIZE')
211    pushdef(`DONE')
212$1
213    popdef(`DONE_SIZE')
214    popdef(`DONE')
215')
216dnl }}}
217dnl {{{ IF**
218define(`IFCALC', `ifelse(KIND, `calc', `$1', `$2')')
219define(`IFSTORE', `ifelse(KIND, `store', `$1', `$2')')
220define(`IFCALCSTORE', `IFSTORE(`$1', `IFCALC(`$1', `$2')')')
221define(`IFRESTORE', `ifelse(KIND, `restore', `$1', `$2')')
222define(`IFCOPY', `IFSTORE(`$1', `IFRESTORE(`$1', `$2')')')
223define(`IFCALCCOPY', `IFCALC(`$1', `IFCOPY(`$1', `$2')')')
224define(`IFDPRINT', `ifelse(KIND, `dprint', `$1', `$2')')
225define(`IFASM', `ifelse(KIND, `asm', `$1', `$2')')
226define(`IFDASM', `ifelse(KIND, `dasm', `$1', `$2')')
227dnl }}}
228EXPORT(`zend_op')
229EXPORT(`zend_op_array')
230EXPORT(`zend_function')
231EXPORT(`HashTable_zend_function')
232EXPORT(`zend_class_entry')
233EXPORT(`xc_classinfo_t')
234EXPORT(`xc_funcinfo_t')
235EXPORT(`xc_entry_t')
236EXPORT(`zval')
237
238include(srcdir`/processor/hashtable.m4')
239include(srcdir`/processor/string.m4')
240include(srcdir`/processor/struct.m4')
241include(srcdir`/processor/dispatch.m4')
242include(srcdir`/processor/head.m4')
243
244define(`IFNOTMEMCPY', `ifdef(`USEMEMCPY', `', `$1')')
245REDEF(`KIND', `calc') include(srcdir`/processor/processor.m4')
246REDEF(`KIND', `store') include(srcdir`/processor/processor.m4')
247REDEF(`KIND', `restore') include(srcdir`/processor/processor.m4')
248
249REDEF(`IFNOTMEMCPY', `$1')
250#ifdef HAVE_XCACHE_DPRINT
251REDEF(`KIND', `dprint') include(srcdir`/processor/processor.m4')
252#endif /* HAVE_XCACHE_DPRINT */
253#ifdef HAVE_XCACHE_DISASSEMBLER
254REDEF(`KIND', `dasm') include(srcdir`/processor/processor.m4')
255#endif /* HAVE_XCACHE_DISASSEMBLER */
256#ifdef HAVE_XCACHE_ASSEMBLER
257REDEF(`KIND', `asm') include(srcdir`/processor/processor.m4')
258#endif /* HAVE_XCACHE_ASSEMBLER */
259
260ifdef(`EXIT_PENDING', `m4exit(EXIT_PENDING)')
Note: See TracBrowser for help on using the repository browser.